利用8位數碼管顯示時間，原理與4位數碼管顯示的基本一樣
仿真圖：
程序源代碼:
作者：胡琴
聯系qq：1257394091
本程序版本規本人所有可以任意轉載：
技術支持網站：http://www.zg4o1577.cn
本程序已經通過在線軟件仿真和硬件制作.
org 0000h ;程序開始入口地址
sjmp main ;跳轉至主程序
org 000bh ;T0中斷入口地址
ljmp inti0 ;跳轉至T0中斷程序
org 001bh ;T1中斷入口地址
ljmp inti1 ;跳轉至T1中斷程序
org 0030h
main:mov tmod,#11h ;設T0、T1為模式1
mov ie,#8ah ;開T0、T1允許中斷
mov th0,#4ch ;賦T0 50ms初值
mov tl0,#00h
mov th1,#4ch ;賦T1 50ms初值
mov tl1,#00h
mov sp,#60h ;設置堆棧指針
mov 38h,#00 ;鬧鐘分初值
mov 39h,#00 ;鬧鐘時初值
mov 31h,#00 ;時間秒初值
mov 32h,#00 ;時間分初值
mov 33h,#00 ;時間時初值
setb tr0 ;啟動定時器T0
setb tr1 ;啟動定時器T1
loop:lcall display ;調用時間顯示程序
lcall keysan ;調用時間調節按鈕
lcall keynz ;調用鬧鐘控制按鈕
ajmp loop
inti0:push psw ;壓入堆棧指針，保護現場
push acc
clr ea ;關中斷
mov th0,#4ch ;重賦T0定時初值
mov tl0,#00h
inc 3ah ;3ah為50ms計數單元
mov a,3ah
cjne a,#20,out ;1秒計數是否到
mov 3ah,#00 ;清50ms計數初值
inc 31h ;秒加1
mov a,31h
cjne a,#60,out ;60秒計數是否到
mov 31h,#00
inc 32h ;分加1
mov a,32h
cjne a,#60,out ;60分計數是否到
mov 32h,#00
inc 33h ;時加1
mov a,33h
cjne a,#24,out ;24時計數是否到
mov 33h,#00
out: setb ea ;開中斷
pop acc ;彈出堆棧指針，恢復現場
pop psw
reti ;中斷返回
inti1:push psw ;壓入堆棧指針，恢復現場
push acc
clr ea
mov th1,#4ch ;重賦T1定時初值
mov tl1,#00h
inc 71h ;71h為50ms計數單元
mov a,71h
cjne a,#20,out1
mov 71h,#00
mov a,32h ;鬧鐘判斷
cjne a,38h,out1 ;鬧鐘時間分判斷
mov a,33h
cjne a,39h,out1 ;鬧鐘時間時判斷
clr p1.0 ;到鬧鐘時間，清p1.0
out1:setb ea ;開中斷
pop acc
pop psw
reti ;中斷返回
display:mov a,31h ;秒顯示
mov b,#10
div ab
mov 20h,a ;將十位放入20h單元
mov 21h,b ;將個位、余數放入21h單元
disp1: mov a,20h ;秒十位顯示
mov dptr,#table
movc a,@a+dptr ;將A的內容+table內容，結果回存給A
mov p0,a ;將A給P0口
clr p2.6 ;清p2.6,點亮第7位數碼管
lcall del1ms ;調用1ms延時子程序
setb p2.6 ;滅第7位數碼管
disp2: mov a,21h ;秒個位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.7
lcall del1ms
setb p2.7
disp4: mov a,32h ;分顯示
mov b,#10
div ab
mov 22h,a
mov 23h,b
disp5: mov a,22h ;分十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.3
lcall del1ms
setb p2.3
disp6: mov a,23h ;分個位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.4
lcall del1ms
setb p2.4
disp7: mov a,33h ;時顯示
mov b,#10
div ab
mov 24h,a
mov 25h,b
disp8: mov a,24h ;時十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.0
lcall del1ms
setb p2.0
disp9: mov a,25h ;時個位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.1
lcall del1ms
setb p2.1
disp10: mov 34h,#0bfh ;"-"顯示
mov a,34h
mov p0,a
clr p2.5
lcall del1ms
setb p2.5
disp11: mov 35h,#0bfh ;"-"顯示
mov a,35h
mov p0,a
clr p2.2
lcall del1ms
setb p2.2
ret
display1:mov a,38h ;鬧鐘分顯示
mov b,#10
div ab
mov 26h,a
mov 27h,b
d1:mov a,26h ;鬧鐘分十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.3
lcall del1ms
setb p2.3
d2:mov a,27h ;鬧鐘分個位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.4
lcall del1ms
setb p2.4
dispnz: mov a,39h ;鬧鐘時顯示
mov b,#10
div ab
mov 28h,a
mov 29h,b
d5: mov a,28h ;鬧鐘時十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.0
lcall del1ms
setb p2.0
d6: mov a,29h ;鬧鐘時個位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.1
lcall del1ms
setb p2.1
mov 35h,#0bfh ;"-"顯示
mov a,35h
mov p0,a
clr p2.2
lcall del1ms
setb p2.2
ret
table:db 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h ;數字0—9
del1ms:mov r7,#10 ;1ms延時子程序
del1: mov r6,#50
del2:djnz r6,del2
djnz r7,del1
ret
del20ms:mov r5,#40 ;20ms延時子程序
del3: mov r4,#250
del4: djnz r4,del4
djnz r5,del3
ret
keysan:jnb p3.1,key1 ;秒加1按鈕
jnb p3.2,key2 ;分加1按鈕
jnb p3.3,key3 ;時加1按鈕
sjmp keyout
key1: lcall del20ms
jb p3.1,keyout
jnb p3.1,$
inc 31h ;秒加1
mov a,31h
cjne a,#60,keyout
mov 31h,#00
sjmp keyout
key2:lcall del20ms
jb p3.2,keyout
jnb p3.2,$
inc 32h ;分加1
mov a,32h
cjne a,#60,keyout
mov 32h,#00
sjmp keyout
key3:lcall del20ms
jb p3.3,keyout
jnb p3.3,$
inc 33h ;時加1
mov a,33h
cjne a,#24,keyout
mov 33h,#00
sjmp keyout
keyout:ret
keynz:jnb p3.4,keynz4 ;顯示鬧鐘并可修改和顯示當前時間
jnb p3.7,keynz5
jnb p3.5,nz3
jnb p3.6,nz4
sjmp nzout
nzout:ret
nz2:lcall display1
jnb p3.5,nz3
jnb p3.6,nz4
keynz4:jnb p3.4,nz2
sjmp nzout
nz3:lcall del20ms
jb p3.5,nzout
jnb p3.5,$
inc 38h
mov a,38h
cjne a,#60,nzout
mov 38h,#00
sjmp nzout
nz4:lcall del20ms
jb p3.6,nzout
jnb p3.6,$
inc 39h
mov a,39h
cjne a,#24,nzout
mov 39h,#00
sjmp keyout
keynz5:jb p3.7,nzout
jnb p3.7,$
setb p1.0
sjmp nzout
end