|
|
;;;MCU:89S51 COLCK:11.0592MHZ
;;;作者 :LYP103
;;;;; 1．實驗任務: 用MCU來做個電子時鐘,能用按鍵來設置和調整時間
;2 :原理
; 單片機的定時/計數器T0產生定時時間，T0的最大定時為50ms，
;即要定時1秒需要經過20次的50ms的定時。
;對于這20次我們就可以采用軟件的方法來統計了。作為秒計數時間，
;當一秒產生時，秒計數加1，秒計數到60時，分加一，秒清零，分計數到60時，時加一，分清零
;時計數到24時，清零 ，從新開始 。
;***********************************************************************
;;;接線說明:
;;; 16*2的字符LCD插到J9上
;;;J10的1腳和J7的1腳連 ,J10的2和J7的2連,,J10的3和J7的3連, J10的4和J7的4連
;;;注意JP的短路帽不要接
;***********************************************************************
K1 BIT P0.0 ;加一鍵 ,選擇的數據加一
K2 BIT P0.1 ;減一鍵 ,選擇的數據減一
K3 BIT P0.2 ;選擇鍵 ,選擇要調整秒,分還是小時用的
K4 BIT P0.3 ;確定鍵,是退出設定
RS EQU P1.2 ;LCD-RS
RW EQU P1.1 ;LCD-RW
E EQU P1.0 ;LCD-E
ORG 0000H
AJMP MAIN
ORG 000BH
AJMP TIME;T0定時中斷處理程序
MAIN: ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
MOV P2,#01H;清除屏幕
ACALL ENABLE
MOV P2,#38H;8位點陣方式
ACALL ENABLE
MOV P2,#0FH;開顯示
ACALL ENABLE
MOV P2,#06H;移動光標
ACALL ENABLE
MOV P2,#01H;清除屏幕
ACALL ENABLE
MOV p2,#38H;8位點陣方式
ACALL ENABLE
MOV p2,#0ch;0FH;開顯示
ACALL ENABLE
MOV p2,#06H;移動光標
ACALL ENABLE
MOV p2,#80H;顯示位置第一行
ACALL ENABLE
CLR 20H
MOV P0,#0FH
MOV IE,#8aH
MOV TMOD,#051H ;設定定時器工作方式?
MOV TL0,#010H
MOV TH0,#4cH
MOV 30H,#00 ;
MOV 31H,#00 ;秒
MOV 32H,#00 ;分
MOV 33H,#00 ;小時
MOV 34H,#00 ;設定按鍵的數值,1為時,2為分,3為秒
SETB TR0 ;啟動定時式
MAIN1:JNB K3,MAIN2 ;有選擇鍵按下轉
JNB 20H,MAIN1 ;1S是否已到？
CLR 20H
ACALL LCD;顯示時間
mov P2,#90H;光標
call enable
AJMP MAIN1
MAIN2:CLR P1.3
ACALL A10MS ;去抖動
SETB P1.3
JB K3,MAIN1 ;沒有按下返回
MOV 34H,#03H ;設定按鍵的數值置初值
ACALL LCD;顯示時間
ACALL LCDM ;更新LCD的標
MAIN3:JB K3,MAIN4;等按鍵放開
JNB 20H,MAIN3 ;1S是否已到？
CLR 20H
ACALL LCD;顯示時間
ACALL LCDM ;更新LCD的標
AJMP MAIN3
MAIN4:ACALL A10MS
JNB K3,MAIN3
;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;判斷是否有按鍵
MAIN5:MOV P0,#0FH
NOP
NOP
NOP
MOV A,P0 ;讀按鍵的值
ADD A,#0F0H
CPL A ;如沒按鍵按下,那A的數值為0
JNZ MAIN6 ;按鍵按下跳轉
JNB 20H,MAIN5 ;1S是否已到？
CLR 20H
ACALL LCD;顯示時間
ACALL LCDM ;更新LCD的標
AJMP MAIN5
MAIN6:ACALL A10MS ;去抖動
MOV P0,#0FH
NOP
NOP
NOP
MOV A,P0 ;讀按鍵的值
ADD A,#0F0H
CPL A ;如沒按鍵按下,那A的數值為0
JZ MAIN5 ;沒按鍵按下跳轉
;;;;;;;;確定鍵
CLR P1.3
ACALL A10MS ;去抖動
SETB P1.3
JNB K4,MAIN1;確定鍵退出設制
;設定按鍵
JB K3,MAIN7;沒有按鍵按下跳轉
DJNZ 34H,MAINXX ;設定按鍵的數值減一不為0轉
MOV 34H,#03H;設定按鍵的數值從新賦數值
AJMP MAINXX
;+1鍵
MAIN7:JB K2,MAIN10 ;沒有按+1鍵按下跳轉
MOV A,34H ; 34H是設定按鍵的數值,1為時,2為分,3為秒
;秒加一
CJNE A,#03H,MAIN8
INC 31H ;秒加一
MOV A,31H
DA A ;調整為BCD碼
MOV 31H,A
CJNE A,#60H,MAINXX;是不是有60S,沒轉
MOV 31H,#00 ;秒清0
AJMP MAINXX
;分加一
MAIN8:MOV A,34H
CJNE A,#02H,MAIN9
INC 32H ;分加一
MOV A,32H
DA A
MOV 32H,A
CJNE A,#60H,MAINXX ;是不是有一個小時,沒轉
MOV 32H,#00 ; 分清0
AJMP MAINXX
;小時加一
MAIN9:MOV A,34H
CJNE A,#01H,MAINXX
INC 33H ;小時加一
MOV A,33H
DA A
MOV 33H,A
CJNE A,#24H,MAINXX ;是不是到24小時
MOV 33H,#00 ;小時清0
AJMP MAINXX
;;;;;
MAINXX:
;判斷按鍵是否釋放
ACALL LCD;顯示時間
ACALL LCDM ;更新LCD的標
MAINXX1:MOV P0,#0FH
NOP
NOP
NOP
MOV A,P0 ;讀按鍵的值
ADD A,#0F0H
CPL A ;如沒按鍵按下,那A的數值為0
JZ MAINXX2 ;按鍵釋放
JNB 20H,MAINXX1;1S是否已到？
CLR 20H
ACALL LCD;顯示時間
ACALL LCDM ;更新LCD的標
AJMP MAINXX1
MAINXX2:ACALL A10MS ;去抖動
MOV P0,#0FH
NOP
NOP
NOP
MOV A,P0 ;讀按鍵的值
ADD A,#0F0H
CPL A ;如沒按鍵按下,那A的數值為0
JNZ MAINXX1 ;沒釋放
AJMP MAIN5
;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;-1鍵
MAIN10:JB K1,MAINXX
MOV A,34H ; 34H是設定按鍵的數值,1為時,2為分,3為秒
;秒減一
CJNE A,#03H,MAIN12
;秒減一
MOV A,31H ;;BCD碼的減一是用加99來求得
JZ MAIN11
ADD A,#99H
DA A ;調整為BCD碼
MOV 31H,A
CJNE A,#00H,MAINXX;是不是有60S,沒轉
MAIN11:MOV 31H,#59H ;秒恢復60
AJMP MAINXX
;分減一
MAIN12:MOV A,34H
CJNE A,#02H,MAIN14
MOV A,32H ;;BCD碼的減一是用加99來求得
JZ MAIN13
ADD A,#99H
DA A ;調整為BCD碼
MOV 32H,A
CJNE A,#00H,MAINXX;是不是有60S,沒轉
MAIN13:MOV 32H,#59H ;秒恢復60
AJMP MAINXX
;小時減一
MAIN14:MOV A,33H ;;BCD碼的減一是用加99來求得
JZ MAIN15
ADD A,#99H
DA A ;調整為BCD碼
MOV 33H,A
CJNE A,#00H,MAINXX;是不是有0,沒轉
MAIN15:MOV 33H,#23H ;秒恢復23
AJMP MAINXX
NOP
;;;;T0定時中斷處理程序：
TIME: PUSH ACC ;保護現場
PUSH PSW
MOV TL0,#0F8H;06H ;賦定時初值
MOV TH0,#4BH;4CH
INC 30H ;
MOV A,30H
CJNE A,#20,RETI1
MOV 30H,#00H ;一秒鐘時間到
SETB 20H
INC 31H ;秒加一
MOV A,31H
DA A
MOV 31H,A
CJNE A,#60H,RETI1;是不是有60S,沒轉
MOV 31H,#00 ;秒清0
INC 32H ;分加一
MOV A,32H
DA A
MOV 32H,A
CJNE A,#60H,RETI1 ;是不是有一個小時,沒轉
MOV 32H,#00 ; 分清0
INC 33H ;小時加一
MOV A,33H
DA A
MOV 33H,A
CJNE A,#24H,RETI1 ;是不是到24小時
MOV 33H,#00 ;小時清0
RETI1:pop psw
pop acc
reti
;;;;;;;;;;;;;;
;;;;;時間顯示
LCD:
;寫數據 時間顯示: XX : XX : XX;分別時:時:分:秒
MOV P2,#38H;8位點陣方式
ACALL ENABLE
MOV P2,#0FH;開顯示
ACALL ENABLE
MOV P2,#06H;移動光標
ACALL ENABLE
MOV P2,#80H;第一行顯示位置
ACALL ENABLE
MOV DPTR,#table1
a1: mov a,33H ;顯示:時
SWAP A
ANL A,#0FH
movc a,@a+dptr
call write2
MOV A,33H
ANL A,#0FH
movc a,@a+dptr
call write2
MOV A,#":"
call write2
mov a,32H ;顯示:分
SWAP A
ANL A,#0FH
movc a,@a+dptr
call write2
MOV A,32H
ANL A,#0FH
movc a,@a+dptr
call write2
MOV A,#":"
call write2
mov a,31H ;顯示:秒
SWAP A
ANL A,#0FH
movc a,@a+dptr
call write2
MOV A,31H
ANL A,#0FH
movc a,@a+dptr
call write2
ret
LCDM: ;更新LCD的標
MOV A,#7EH
ADD A,34H
ADD A,34H
ADD A,34H
mov P2,A;光標
call enable
RET
write2:
mov P2,a
setb rs
clr rw
clr e
ACALL delay
setb e
ret
ENABLE:
CLR RS
CLR RW
CLR E
ACALL DELAY
SETB E
RET
delay: ;寫延時,等待寫完成
mov r7,#30
d1: mov r6,#25
d2: djnz r6,d2
djnz r7,d1
ret
;0 1 2 3 4 5 6 7 8 9
table1:DB 30H,31H,32H,33H,34H,35H,36H,37H,3 ;返回
A10MS: MOV R6,#09
A10MS1: MOV R7,#0FFH
A10MS2: NOP
NOP
DJNZ R7,A10MS2
DJNZ R6,A10MS1
|
|
QQ好友和群
QQ空間
騰訊微博
騰訊朋友
收藏
淘帖
頂
踩
