久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

 找回密碼
 立即注冊

QQ登錄

只需一步，快速開始

搜索
查看: 4168|回復(fù): 1
收起左側(cè)

多功能檢測儀程序（4路溫度控制）

[復(fù)制鏈接]
ID:70976 發(fā)表于 2014-12-26 23:39 | 顯示全部樓層 |閱讀模式
  1. ;*******************************************************************
  2. ;*溫度控制程序,在LCD屏幕上顯示4路溫度（車內(nèi)外溫度、水溫、油溫）
  3. ;分兩頁顯示，每頁顯示2路溫度，溫度傳感器開路時語音報警和顯示故障
  4. ;水溫、油溫超溫報警
  5. ;*LCD12864顯示，晶振11.0592M
  6. ;*******************************************************************
  7. ;-----------------------------------------------------------
  8. ;以下參數(shù)可以修改
  9. ;-----------------------------------------------------------
  10.           XSYSSJ    DATA   40     ;顯示延時時間
  11.           XSGZSJ    DATA   40     ;故障顯示延時時間
  12.           CNBJCS    DATA   2      ;車內(nèi)溫度傳感器出故障報警次數(shù)
  13.           CWBJCS    DATA   2      ;車外溫度傳感器出故障報警次數(shù)
  14.           SWBJCS    DATA   2      ;水溫傳感器故出障報警次數(shù)
  15.           YWBJCS    DATA   2      ;油溫度傳感器出故障報警次數(shù)
  16.           SWGWSD    DATA   50     ;水溫超高報警值（單位℃）
  17.           SWDWSD    DATA   23     ;水溫超低報警值（單位℃）
  18.           YWGWSD    DATA   40     ;油溫超高報警值（單位℃）
  19.           YWDWSD    DATA   25     ;油溫超低報警值（單位℃）
  20.          
  21. ;-----------------------------------------------------------
  22. ;以下參數(shù)不宜修改
  23. ;-----------------------------------------------------------
  24.           FLAG0     BIT   20H.0   ;車內(nèi)溫度傳感器標(biāo)志
  25.           FLAG1     BIT   20H.1   ;車外溫度傳感器標(biāo)志
  26.           FLAG2     BIT   20H.2   ;水溫傳感器標(biāo)志
  27.           FLAG3     BIT   20H.3   ;油溫傳感器標(biāo)志

  29.           FLAG4     BIT   20H.4   ;車內(nèi)溫度傳感器故障標(biāo)志位，1為故障0為正常
  30.           FLAG5     BIT   20H.5   ;車外溫度傳感器故障標(biāo)志位，1為故障0為正常
  31.           FLAG6     BIT   20H.6   ;水溫傳感器故障標(biāo)志位，1為故障0為正常
  32.           FLAG7     BIT   20H.7   ;油溫傳感器故障標(biāo)志位，1為故障0為正常

  34.           FLAH0     BIT   21H.0   ;溫度正負(fù)標(biāo)志，1為負(fù)0為正，正不顯示
  35.           FLAH1     BIT   21H.1   ;水溫過高標(biāo)志，1為過高
  36.           FLAH2     BIT   21H.2   ;油溫過高標(biāo)志，1為過高

  38. ;-----------------------------------------------------------
  39.           XSYS      DATA  22H     ;顯示延時時間存放單元
  40.           LCD_X     EQU   23H     ;LCD 地址變量

  42.           TEMP_ZH   DATA  24H     ;實時溫度值存放單元
  43.           TEMPL     DATA  25H     ;溫度低位值存放單元
  44.           TEMPH     DATA  26H     ;溫度高位值存放單元
  45.           TEMP_TH   DATA  27H     ;高溫報警值存放單元
  46.           TEMP_TL   DATA  28H     ;低溫報警值存放單元
  47.           YY_DAT    DATA  29H     ;語音地址存放單元

  49.           CNBJ      DATA  2AH     ;車內(nèi)溫度傳感器故障報警次數(shù)存放單元
  50.           CWBJ      DATA  2BH     ;車外溫度傳感器故障報警次數(shù)存放單元
  51.           SWBJ      DATA  2CH     ;水溫傳感器故障報警次數(shù)存放單元
  52.           YWBJ      DATA  2DH     ;油溫傳感器故障報警次數(shù)存放單元

  54.           YYDAT     DATA  2EH     ;語音發(fā)碼值暫存地址
  55. ;-----------------------------------------------------------
  56.           CNCGBJ    DATA   30     ;“車內(nèi)溫度傳感器出故障，請檢查”語音地址
  57.           CWCGBJ    DATA   31     ;“車外溫度傳感器出故障，請檢查”語音地址
  58.           SWCGBJ    DATA   32     ;“水溫傳感器出故障，請檢查”語音地址
  59.           YWCGBJ    DATA   33     ;“油溫傳感器出故障，請檢查”語音地址
  60. ;-----------------------------------------------------------
  61. ;以下參數(shù)是固定的，不要修改
  62. ;-----------------------------------------------------------
  63.           YYRST     EQU   P3.3    ;語音模塊復(fù)位信號引腳
  64.           BUSY      EQU   P1.0    ;語音忙控制端，0為正在播放1為沒有播放
  65.           YYSDA     EQU   P1.1    ;語音模塊數(shù)據(jù)引腳

  67.           CG_CHENEI EQU   P1.4    ;車內(nèi)溫度傳感器數(shù)據(jù)線
  68.           CG_CHEWAI EQU   P1.5    ;車外溫度傳感器數(shù)據(jù)線
  69.           CG_SHUIWE EQU   P1.6    ;水溫傳感器數(shù)據(jù)線
  70.           CG_YOUWEN EQU   P1.7    ;油溫傳感器數(shù)據(jù)線
  71. ;-----------------------------------------------------------
  72.           LCD_RS    EQU   P4.0    ;LCD 數(shù)據(jù)/命令選擇端
  73.           LCD_RW    EQU   P4.1    ;LCD 讀/寫選擇端
  74.           LCD_EN    EQU   P4.2    ;LCD 使能信號
  75.           LCD_BG    EQU   P4.3    ;LCD 背光控制端
  76.           LCD_SJ    EQU   P0      ;LCD 數(shù)據(jù)




  81. ;===========================================================
  82.           ORG  0000H
  83.           AJMP  MAIN
  84.           ORG  0100H
  85. ;===========================================================
  86. MAIN:     MOV  SP,#60H
  87.           MOV  A,#00H
  88.           MOV  R0,#20H         ;將 20H-2FH 單元清零
  89.           MOV  R1,#10H
  90. CLEAR:    MOV  @R0,A
  91.           INC  R0
  92.           DJNZ  R1,CLEAR
  93.           CLR  LCD_BG          ;打開LCD背光

  95.           CALL  SET_LCD        ;初始化 LCD

  97.           MOV   CNBJ,#CNBJCS   ;設(shè)置車內(nèi)溫度傳感器故障報警次數(shù)
  98.           MOV   CWBJ,#CWBJCS   ;設(shè)置車外溫度傳感器故障報警次數(shù)
  99.           MOV   SWBJ,#SWBJCS   ;設(shè)置水溫傳感器故障報警次數(shù)
  100.           MOV   YWBJ,#YWBJCS   ;設(shè)置油溫傳感器故障報警次數(shù)

  102.           ;LCALL TEMP



  106. ;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  107. ;##########################################################
  108. ;以下溫度顯示程序（車內(nèi)外溫度、水溫、油溫）
  109. ;-----------------------------------------------------------
  110. ;用到的資源：R0～R7,A、B、C，20H～2EH,P4，P3.3，P1.0，P1.4～P1.7
  111. ;-----------------------------------------------------------
  112. ;##########################################################
  113. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  114. ;**************顯示第一頁溫度（車內(nèi)外溫度）

  116. TEMP:     CALL  MENU_OK1       ;顯示溫度菜單1

  118.           MOV TEMP_TH,#00H     ;溫度低位值存放單元
  119.           MOV TEMP_TL,#00H     ;溫度低位值存放單元

  121.           SETB  FLAG0          ;開始讀取車內(nèi)溫度傳感器，設(shè)標(biāo)志為1
  122.           CLR FLAG1
  123.           CLR FLAG2
  124.           CLR FLAG3
  125.           MOV  XSYS,#XSYSSJ    ;每頁顯示時間

  127. ;讀取和顯示車內(nèi)溫度
  128. L1:       CALL  RESET          ;18B20復(fù)位子程序
  129.           JB   FLAG4,L2        ;檢查車外溫度傳感器是否正常
  130.           CALL  BJ1            ;調(diào)用報警程序
  131.           MOV  XSYS,#XSGZSJ    ;重新設(shè)每頁顯示時間
  132.           SJMP  L3             ;傳感器出故障不再顯示該溫度
  133. L2:       CALL  READ_TEMP      ;讀出溫度與報警數(shù)據(jù)
  134.           CALL  CONVTEMP       ;轉(zhuǎn)換處理溫度為BCD碼
  135.           CALL  CONV01         ;顯示車內(nèi)溫度

  137. L3:       CLR FLAG0
  138.           SETB FLAG1
  139.           CLR FLAG2
  140.           CLR FLAG3

  142. ;讀取和顯示車外溫度
  143.           CALL  RESET          ;18B20復(fù)位子程序
  144.           JB   FLAG5,L4        ;檢查車內(nèi)溫度傳感器是否正常
  145.           CALL  BJ2            ;調(diào)用報警程序
  146.           SJMP  L5             ;傳感器出故障不再顯示該溫度
  147. L4:       CALL  READ_TEMP      ;讀出溫度與報警數(shù)據(jù)
  148.           CALL  CONVTEMP       ;轉(zhuǎn)換處理溫度為BCD碼
  149.           CALL  CONV02         ;顯示車外溫度

  151. L5:       SETB FLAG0
  152.           CLR FLAG1
  153.           CLR FLAG2
  154.           CLR FLAG3

  156.           JB FLAG4,L71
  157.           JB FLAG5,L71

  159.           MOV R0,#XSGZSJ
  160. L70:      ACALL DELAY
  161.           DJNZ R0,L70
  162.           SJMP L6

  164. L71:      ACALL DELAY          ;延時
  165.           DEC XSYS             ;車內(nèi)外溫度顯示頁顯示一段時間，以便觀察
  166.           MOV A,XSYS
  167.           JZ L6
  168.           SJMP L1

  170. ;**************顯示第二頁溫度（水溫和油溫）

  172. L6:       CALL  MENU_OK2       ;顯示溫度菜單2
  173.           MOV  XSYS,#XSYSSJ    ;重新設(shè)每頁顯示時間
  174.           CLR FLAG0
  175.           CLR FLAG1
  176.           SETB FLAG2
  177.           CLR FLAG3

  179. ;讀取和顯示水溫
  180. L7:       CALL  RESET          ;傳感器復(fù)位子程序
  181.           JB   FLAG6,L8        ;檢查水溫傳感器是否正常
  182.           CALL  BJ3            ;調(diào)用報警程序
  183.           SJMP  L9
  184. L8:       CALL  READ_TEMP      ;讀出溫度與報警數(shù)據(jù)
  185.           CALL  CONVTEMP       ;轉(zhuǎn)換處理溫度為BCD碼
  186.           CALL  TEMP_COMP      ;溫度比較子程序
  187.           CALL  CONV01         ;顯示水溫

  189. L9:       CLR FLAG0
  190.           CLR FLAG1
  191.           CLR FLAG2
  192.           SETB FLAG3

  194. ;讀取和顯示油溫
  195.           CALL  RESET          ;傳感器復(fù)位子程序
  196.           JB   FLAG7,L10       ;檢查油溫傳感器是否正常
  197.           CALL  BJ4            ;調(diào)用報警程序
  198.           SJMP  L11
  199. L10:      CALL  READ_TEMP      ;讀出溫度與報警數(shù)據(jù)
  200.           CALL  CONVTEMP       ;轉(zhuǎn)換處理溫度為BCD碼
  201.           CALL  TEMP_COMP      ;溫度比較子程序
  202.           CALL  CONV02         ;顯示油溫

  204. L11:      CLR FLAG0
  205.           CLR FLAG1
  206.           SETB FLAG2
  207.           CLR FLAG3

  209.           JB FLAG6,L81
  210.           JB FLAG7,L81

  212.           MOV R0,#XSGZSJ
  213. L80:      ACALL DELAY
  214.           DJNZ R0,L80
  215.           SJMP L82

  217. L81:      ACALL DELAY
  218.           DEC XSYS              ;水溫、油溫顯示頁顯示一段時間，以便觀察
  219.           MOV A,XSYS
  220.           JZ L82
  221.           AJMP L7
  222. L82:      AJMP MAIN
  223.           RET

  225. ;------------------------------------------------------
  226. ;報警程序，傳感器故障聲音報警和LCD顯示
  227. ;------------------------------------------------------
  228. BJ1:      MOV A,CNBJ        ;車內(nèi)溫度故障報警和顯示
  229.           JZ L13            ;聲音報警N次后不再報警,只顯示故障
  230.           MOV YY_DAT,#CNCGBJ;報出“車內(nèi)溫度傳感器出故障，請檢查”
  231.           JNB BUSY,L13      ;如果正在播放語音則跳過,只顯示故障
  232.           DEC CNBJ          ;車內(nèi)溫度傳感器語音報警次數(shù)倒計數(shù)
  233.           SJMP L12          ;故障語音報警

  235. BJ2:      MOV A,CWBJ        ;車外溫度故障報警和顯示
  236.           JZ L15            ;聲音報警N次后不再報警,只顯示故障
  237.           MOV YY_DAT,#CWCGBJ;報出“車外溫度傳感器出故障，請檢查”
  238.           JNB BUSY,L15      ;如果正在播放語音則跳過,只顯示故障
  239.           DEC CWBJ          ;車外溫度傳感器語音報警次數(shù)倒計數(shù)
  240.           SJMP L14          ;故障顯示

  242. BJ3:      MOV A,SWBJ        ;水溫故障報警和顯示
  243.           JZ L13            ;聲音報警N次后不再報警,只顯示故障
  244.           MOV YY_DAT,#SWCGBJ;報出“水溫傳感器出故障，請檢查”
  245.           JNB BUSY,L13      ;如果正在播放語音則跳過,只顯示故障
  246.           DEC SWBJ          ;水溫傳感器語音報警次數(shù)倒計數(shù)
  247. L12:      ACALL YUYIN       ;語音播放
  248. L13:      MOV  A,#90H        ;顯示在第二行
  249.           SJMP L16          ;故障顯示

  251. BJ4:      MOV A,YWBJ        ;油溫故障報警和顯示
  252.           JZ L15            ;聲音報警N次后不再報警,只顯示故障
  253.           MOV YY_DAT,#YWCGBJ;報出“油溫傳感器出故障，請檢查”
  254.           JNB BUSY,L15      ;如果正在播放語音則跳過,只顯示故障
  255.           DEC YWBJ          ;油溫傳感器語音報警次數(shù)倒計數(shù)
  256. L14:      ACALL YUYIN       ;語音播放
  257. L15:      MOV  A,#98H       ;顯示在第四行

  259. L16:      MOV  DPTR,#MUNE1  ;指針指到顯示信息區(qū)
  260.           CALL  WCOM
  261. L203:     CLR  A            ;填入字符
  262.           MOVC  A,@A+DPTR   ;由信息區(qū)取出字符
  263.           CJNE  A,#0,L205   ;判斷是否為結(jié)束碼
  264.           RET

  266. L205:     CALL  WDATA       ;寫入數(shù)據(jù)
  267.           INC  DPTR         ;指針加1
  268.           JMP  L203         ;繼續(xù)填入字符

  270. MUNE1:    DB"探頭故障請檢查！",0 ;溫度探頭不正常報警程序

  272. ;--------------------------------------------------------------------
  273. ;傳感器讀溫度子程序
  274. ; 將溫度低位、高位、TH、TL從傳感器中讀出
  275. ; 分別存入 25H、26H、27H、28H 單元中
  276. ;--------------------------------------------------------------------
  277. READ_TEMP:MOV   A,#0CCH        ; 跳過ROM匹配
  278.          CALL  WRITE
  279.          MOV   A,#44H          ; 發(fā)出溫度轉(zhuǎn)換命令
  280.          CALL  WRITE
  281.          CALL  RESET
  282.          MOV   A,#0CCH         ; 跳過ROM匹配
  283.          CALL  WRITE
  284.          MOV   A,#0BEH         ; 發(fā)出讀溫度命令
  285.          CALL  WRITE           ;先寫入命令

  287.          MOV R4,#4             ;存入4個單元中
  288.          MOV R1,#TEMPL         ;存入單元的首地址送入 R1
  289. RE00:    MOV R2,#8             ;8位數(shù)據(jù)長度
  290. RE01:    CLR CY
  291. ;***********************
  292.          JNB FLAG0,L01
  293.          SETB CG_CHENEI
  294.          NOP
  295.          NOP
  296.          CLR CG_CHENEI        ;讀前總線保持為低
  297.          NOP
  298.          NOP
  299.          NOP
  300.          SETB CG_CHENEI       ;開始讀總線釋放
  301.          MOV R3,#07           ;延時15微妙
  302.          DJNZ R3,$
  303.          MOV C,CG_CHENEI      ;從傳感器總線讀得一個BIT
  304.          AJMP L5A

  306. L01:     JNB FLAG1,L02
  307.          SETB CG_CHEWAI
  308.          NOP
  309.          NOP
  310.          CLR CG_CHEWAI        ;讀前總線保持為低
  311.          NOP
  312.          NOP
  313.          NOP
  314.          SETB CG_CHEWAI       ;開始讀總線釋放
  315.          MOV R3,#07           ;延時15微妙
  316.          DJNZ R3,$
  317.          MOV C,CG_CHEWAI      ;從傳感器總線讀得一個BIT
  318.          AJMP L5A

  320. L02:     JNB FLAG2,L03
  321.          SETB CG_SHUIWE
  322.          NOP
  323.          NOP
  324.          CLR CG_SHUIWE        ;讀前總線保持為低
  325.          NOP
  326.          NOP
  327.          NOP
  328.          SETB CG_SHUIWE       ;開始讀總線釋放
  329.          MOV R3,#07           ;延時15微妙
  330.          DJNZ R3,$
  331.          MOV C,CG_SHUIWE      ;從傳感器總線讀得一個BIT
  332. L0:      AJMP L5A

  334. L03:     JNB FLAG3,L0
  335.          SETB CG_YOUWEN
  336.          NOP
  337.          NOP
  338.          CLR CG_YOUWEN        ;讀前總線保持為低
  339.          NOP
  340.          NOP
  341.          NOP
  342.          SETB CG_YOUWEN       ;開始讀總線釋放
  343.          MOV R3,#07           ;延時15微妙
  344.          DJNZ R3,$
  345.          MOV C,CG_YOUWEN      ;從傳感器總線讀得一個BIT
  346. ;*****************************
  347. L5A:     MOV R3,#3CH
  348.          DJNZ R3,$            ;等待100微妙
  349.          RRC A                ;把讀得的位值環(huán)移給A
  350.          DJNZ R2,RE01         ;讀下一個BIT
  351.          MOV @R1,A
  352.          INC R1
  353.          DJNZ R4,RE00         ;沒有讀完，繼續(xù)
  354. ;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  355. ;         JB FLAG0,L000
  356. ;         PUSH A
  357. ;         MOV A,#WENDSD
  358. ;         CLR C
  359. ;         SUBB  A,TEMPL      ;減數(shù)>被減數(shù)，則
  360. ;        JC L00
  361. ;         SETB FLAH3
  362. ;L00:     POP A
  363. L000:    RET
  364. ;*****************************************************
  365. ;處理溫度 BCD 碼子程序
  366. ;整數(shù)部分:取出 TEMPL 高四位和 TEMPH 低四位進(jìn)行重新組合
  367. ;小數(shù)部分:取出 TEMPL 低四位,查小數(shù)碼表
  368. ;****************************************************
  369. CONVTEMP:MOV  A,TEMPH       ;判溫度是否零下
  370.          ANL  A,#80H
  371.          JZ  TEMPC1         ;溫度零上轉(zhuǎn)
  372.          SETB FLAH0         ;溫度為負(fù)值
  373.          CLR  C
  374.          MOV  A,TEMPL       ;二進(jìn)制數(shù)求補(bǔ)（雙字節(jié)）
  375.          CPL  A             ;取反加1
  376.          ADD  A,#01H
  377.          MOV  TEMPL,A
  378.          MOV  A,TEMPH
  379.          CPL  A
  380.          ADDC  A,#00H
  381.          MOV  TEMPH,A
  382.          JMP  TEMPC2

  384. TEMPC1:  CLR  FLAH0               ;溫度為正值
  385. TEMPC2:  MOV  A,TEMPL
  386.          ANL  A,#0FH              ;取出小數(shù)部分
  387.          MOV  B,#10               ;將TEMP_L的低四位X10/16得小數(shù)后一位數(shù).
  388.          MUL  AB
  389.   MOV  B,#16
  390.   DIV  AB
  391.          MOV  70H,A               ;小數(shù)部分 BCD

  393.          MOV  A,TEMPL             ;整數(shù)部分
  394.          ANL  A,#0F0H             ;取出高四位
  395.          SWAP  A
  396.          MOV  TEMPL,A
  397.          MOV  A,TEMPH             ;取出低四位
  398.          ANL  A,#0FH
  399.          SWAP  A
  400.          ORL  A,TEMPL             ;重新組合溫度數(shù)據(jù)
  401.          MOV  TEMP_ZH,A           ;重新組合的溫度數(shù)據(jù)存入TEMP_ZH
  402.          LCALL  HEX2BCD1

  404.          MOV  TEMPL,A             ;(A)＝十位數(shù)和個位數(shù)
  405.          ANL  A,#0F0H
  406.          SWAP  A
  407.          MOV  72H,A               ;十位數(shù) BCD
  408.          MOV  A,TEMPL
  409.          ANL  A,#0FH
  410.          MOV  71H,A               ;個位數(shù) BCD
  411.          MOV  A,R4                ;(R4)= 百位數(shù)
  412.          MOV  73H,A

  414. TEMPC3:  RET
  415. ;====================================================
  416. ;單字節(jié)十六進(jìn)制轉(zhuǎn)BCD
  417. ;入口：(A)=單字節(jié)十六進(jìn)制的溫度值
  418. ;出口：(R4)= 百位數(shù)，(A)=十位數(shù)和個位數(shù)
  419. ;====================================================
  420. HEX2BCD1:MOV  B,#64H
  421.          DIV  AB
  422.          MOV  R4,A             ;(R4)＝百位數(shù)
  423.          MOV  A,#0AH
  424.          XCH  A,B
  425.          DIV  AB
  426.          SWAP  A
  427.          ORL  A,B             ;(A)＝十位數(shù)和個位數(shù)
  428.          RET

  430. ;==========================================================
  431. ; LCD 溫度值顯示子程序
  432. ;73H-70H 分別存放百位、十位、個位、小數(shù)位的數(shù)據(jù)
  433. ;==========================================================
  434. CONV01:   MOV  A,73H         ;加載百位數(shù)據(jù)
  435.           MOV  LCD_X,#1      ;設(shè)置顯示位置
  436.           JNB  FLAH0,CONV0   ;
  437.           MOV  A,#"-"        ;顯示"-"
  438.           MOV  B,LCD_X
  439.           CALL  LCDP2

  441.           MOV  A,72H         ;十位
  442.           CJNE A,#00H,CONV3
  443.           INC  LCD_X         ;調(diào)整顯示地址
  444.           MOV  A,#" "        ;十位數(shù)等于0顯示空格
  445.           MOV  B,LCD_X
  446.           CALL  LCDP2
  447.           JMP  CONV4

  449. CONV0:    CJNE A,#00H,CONV2

  451. CONV1:    MOV  A,#" "        ;百位數(shù)等于0顯示空格
  452.           MOV  B,LCD_X
  453.           CALL  LCDP2
  454.           MOV  A,72H         ;十位
  455.           CJNE A,#00H,CONV3
  456.           INC  LCD_X         ;調(diào)整顯示地址
  457.           MOV  A,#" "        ;十位數(shù)等于0顯示空格
  458.           MOV  B,LCD_X
  459.           CALL  LCDP2
  460.           JMP  CONV4

  462. CONV2:    CALL  SHOW_DIG2    ;顯示數(shù)據(jù)

  464. CONV3:    INC  LCD_X         ;調(diào)整顯示地址
  465.           MOV  A,72H         ;十位
  466.           CALL  SHOW_DIG2

  468. CONV4:    INC  LCD_X         ;調(diào)整顯示地址
  469.           MOV  A,71H         ;個位
  470.           CALL  SHOW_DIG2
  471.           INC  LCD_X         ;調(diào)整顯示地址
  472.           MOV  A,#'.'
  473.           MOV  B,LCD_X
  474.           CALL  LCDP2
  475.           MOV  A,70H         ;加載小數(shù)位
  476.           INC  LCD_X         ;設(shè)置位置
  477.           CALL  SHOW_DIG2    ;顯示數(shù)據(jù)
  478.           RET
  479. ;=============================================
  480. ;在LCD的第二行顯示數(shù)據(jù)字符
  481. ;A=ASCII 數(shù)據(jù), B=位置變量
  482. ;==============================================
  483. LCDP2:   PUSH  ACC        ;在LCD的第二行顯示字符
  484.          MOV  A,B         ;設(shè)置顯示地址
  485.          ADD  A,#90H     ;設(shè)置LCD的第二行地址
  486.          CALL  WCOM       ;寫入命令
  487.          POP  ACC         ;由堆棧取出A
  488.          CALL  WDATA      ;寫入數(shù)據(jù)
  489.          RET
  490. ;-------------------------------------------------------
  491. SHOW_DIG2:                 ;在 LCD 的第二行顯示數(shù)字
  492.           ADD  A,#30H      ;加30H，轉(zhuǎn)換為ASCII碼
  493.           MOV  B,LCD_X     ;確定顯示位置
  494.           CALL  LCDP2      ;送顯示
  495.           RET
  496. ;*************************************************************************
  497. ;==========================================================
  498. ; LCD 溫度值顯示子程序2，顯示在第四行
  499. ;73H-70H 分別存放百位、十位、個位、小數(shù)位的數(shù)據(jù)
  500. ;==========================================================
  501. CONV02:   MOV  A,73H         ;加載百位數(shù)據(jù)
  502.           MOV  LCD_X,#1      ;設(shè)置顯示位置
  503.           JNB  FLAH0,CONV10   ;
  504.           MOV  A,#"-"        ;顯示"-"
  505.           MOV  B,LCD_X
  506.           CALL  LCDP4

  508.           MOV  A,72H         ;十位
  509.           CJNE A,#00H,CONV13
  510.           INC  LCD_X         ;調(diào)整顯示地址
  511.           MOV  A,#" "        ;十位數(shù)等于0顯示空格
  512.           MOV  B,LCD_X
  513.           CALL  LCDP4
  514.           JMP  CONV14

  516. CONV10:   CJNE A,#00H,CONV12

  518. CONV11:   MOV  A,#" "        ;百位數(shù)等于0顯示空格
  519.           MOV  B,LCD_X
  520.           CALL  LCDP4
  521.           MOV  A,72H         ;十位
  522.           CJNE A,#00H,CONV13
  523.           INC  LCD_X         ;調(diào)整顯示地址
  524.           MOV  A,#" "        ;十位數(shù)等于0顯示空格
  525.           MOV  B,LCD_X
  526.           CALL  LCDP4
  527.           JMP  CONV14

  529. CONV12:   CALL  SHOW_DIG4    ;顯示數(shù)據(jù)

  531. CONV13:   INC  LCD_X         ;調(diào)整顯示地址
  532.           MOV  A,72H         ;十位
  533.           CALL  SHOW_DIG4

  535. CONV14:   INC  LCD_X         ;調(diào)整顯示地址
  536.           MOV  A,71H         ;個位
  537.           CALL  SHOW_DIG4
  538.           INC  LCD_X         ;調(diào)整顯示地址
  539.           MOV  A,#'.'
  540.           MOV  B,LCD_X
  541.           CALL  LCDP4
  542.           MOV  A,70H         ;加載小數(shù)位
  543.           INC  LCD_X         ;設(shè)置位置
  544.           CALL  SHOW_DIG4    ;顯示數(shù)據(jù)
  545.           RET
  546. ;=============================================
  547. ;在LCD的第二行顯示數(shù)據(jù)字符
  548. ;A=ASCII 數(shù)據(jù), B=位置變量
  549. ;==============================================
  550. LCDP4:   PUSH  ACC        ;在LCD的第二行顯示字符
  551.          MOV  A,B         ;設(shè)置顯示地址
  552.          ADD  A,#98H      ;設(shè)置LCD的第二行地址
  553.          CALL  WCOM       ;寫入命令
  554.          POP  ACC         ;由堆棧取出A
  555.          CALL  WDATA      ;寫入數(shù)據(jù)
  556.          RET
  557. ;-------------------------------------------------------
  558. SHOW_DIG4:                 ;在 LCD 的第二行顯示數(shù)字
  559.           ADD  A,#30H      ;加30H，轉(zhuǎn)換為ASCII碼
  560.           MOV  B,LCD_X     ;確定顯示位置
  561.           CALL  LCDP4      ;送顯示
  562.           RET
  563. ;*************************************************************************
  564. ;------------------------------------------------------------------
  565. ;傳感器 寫命令、數(shù)據(jù)子程序
  566. ;根據(jù)命令的內(nèi)容，進(jìn)行寫操作
  567. ;------------------------------------------------------------------
  568. WRITE:  MOV R2,#8            ;8位數(shù)據(jù)長度
  569.         CLR  C
  570. WR1:    JNB FLAG0,L21
  571.         CLR CG_CHENEI        ;開始寫入傳感器總線要處于復(fù)位（低）狀態(tài)
  572.         MOV R3,#08
  573.         DJNZ R3,$            ;總線復(fù)位保持16微妙以上
  574.         RRC A                ;把一個字節(jié)DATA 分成8個BIT環(huán)移給C
  575.         MOV CG_CHENEI,C      ;寫入一個BIT
  576.         MOV R3,#3CH
  577.         DJNZ R3,$            ;等待120微妙
  578.         SETB CG_CHENEI       ;重新釋放總線
  579.         NOP
  580.         DJNZ R2,WR1          ;寫入下一個BIT
  581.         SETB CG_CHENEI
  582.         RET

  584. L21:    JNB FLAG1,L22
  585.         CLR CG_CHEWAI        ;開始寫入傳感器總線要處于復(fù)位（低）狀態(tài)
  586.         MOV R3,#08
  587.         DJNZ R3,$            ;總線復(fù)位保持16微妙以上
  588.         RRC A                ;把一個字節(jié)DATA 分成8個BIT環(huán)移給C
  589.         MOV CG_CHEWAI,C      ;寫入一個BIT
  590.         MOV R3,#3CH
  591.         DJNZ R3,$            ;等待120微妙
  592.         SETB CG_CHEWAI       ;重新釋放總線
  593.         NOP
  594.         DJNZ R2,WR1          ;寫入下一個BIT
  595.         SETB CG_CHEWAI
  596.         RET

  598. L22:    JNB FLAG2,L23
  599.         CLR CG_SHUIWE        ;開始寫入傳感器總線要處于復(fù)位（低）狀態(tài)
  600.         MOV R3,#08
  601.         DJNZ R3,$            ;總線復(fù)位保持16微妙以上
  602.         RRC A                ;把一個字節(jié)DATA 分成8個BIT環(huán)移給C
  603.         MOV CG_SHUIWE,C      ;寫入一個BIT
  604.         MOV R3,#3CH
  605.         DJNZ R3,$            ;等待120微妙
  606.         SETB CG_SHUIWE       ;重新釋放總線
  607.         NOP
  608.         DJNZ R2,WR1          ;寫入下一個BIT
  609.         SETB CG_SHUIWE
  610.         RET

  612. L23:    JNB FLAG3,L24
  613.         CLR CG_YOUWEN        ;開始寫入傳感器總線要處于復(fù)位（低）狀態(tài)
  614.         MOV R3,#08
  615.         DJNZ R3,$            ;總線復(fù)位保持16微妙以上
  616.         RRC A                ;把一個字節(jié)DATA 分成8個BIT環(huán)移給C
  617.         MOV CG_YOUWEN,C      ;寫入一個BIT
  618.         MOV R3,#3CH
  619.         DJNZ R3,$            ;等待120微妙
  620.         SETB CG_YOUWEN       ;重新釋放總線
  621.         NOP
  622.         DJNZ R2,WR1          ;寫入下一個BIT
  623.         SETB CG_YOUWEN
  624. L24:    RET

  626. ;=================================================
  627. MENU_OK1: MOV  DPTR,#M_OK11  ;指針指到顯示信息區(qū)
  628.           MOV  A,#1          ;顯示在第一行
  629.           CALL  LCD_PRINT
  630.           MOV  DPTR,#M_OK12  ;指針指到顯示信息區(qū)
  631.           MOV  A,#2          ;顯示在第二行
  632.           CALL  LCD_PRINT
  633.           MOV  DPTR,#M_OK13  ;指針指到顯示信息區(qū)
  634.           MOV  A,#3          ;顯示在第二行
  635.           CALL  LCD_PRINT
  636.           MOV  DPTR,#M_OK14  ;指針指到顯示信息區(qū)
  637.           MOV  A,#4          ;顯示在第二行
  638.           CALL  LCD_PRINT
  639.           RET
  640. M_OK11:   DB"車內(nèi)溫度：      ",0
  641. M_OK12:   DB"            ℃ ",0
  642. M_OK13:   DB"車外溫度：      ",0
  643. M_OK14:   DB"            ℃ ",0
  644. ;=================================================
  645. MENU_OK2: MOV  DPTR,#M_OK21  ;指針指到顯示信息區(qū)
  646.           MOV  A,#1          ;顯示在第一行
  647.           CALL  LCD_PRINT
  648.           MOV  DPTR,#M_OK22  ;指針指到顯示信息區(qū)
  649.           MOV  A,#2          ;顯示在第二行
  650.           CALL  LCD_PRINT
  651.           MOV  DPTR,#M_OK23  ;指針指到顯示信息區(qū)
  652.           MOV  A,#3          ;顯示在第二行
  653.           CALL  LCD_PRINT
  654.           MOV  DPTR,#M_OK24  ;指針指到顯示信息區(qū)
  655.           MOV  A,#4          ;顯示在第二行
  656.           CALL  LCD_PRINT
  657.           RET
  658. M_OK21:   DB"水溫：         ",0
  659. M_OK22:   DB"            ℃ ",0
  660. M_OK23:   DB"油溫：         ",0
  661. M_OK24:   DB"            ℃ ",0

  663. ;==================================================
  664. ;在LCD的第一行或第二行顯示字符串
  665. ;DPTR = 放字符串的地址
  666. ;==================================================
  667. LCD_PRINT:CJNE  A,#1,LINE2  ;判斷是否為第一行
  668. LINE1:    MOV  A,#80H       ;設(shè)置 LCD 的第一行地址
  669.           CALL  WCOM        ;寫入命令
  670.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  671.           MOV  A,#80H       ;設(shè)置 LCD 的第一行地址
  672.           CALL  WCOM        ;寫入命令
  673.           JMP  FILL

  675. LINE2:    CJNE  A,#2,LINE3  ;判斷是否為第二行
  676.           MOV  A,#90H       ;設(shè)置 LCD 的第二行地址
  677.           CALL  WCOM        ;寫入命令
  678.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  679.           MOV  A,#90H       ;設(shè)置 LCD 的第二行地址
  680.           CALL  WCOM
  681.           JMP  FILL

  683. LINE3:    CJNE  A,#3,LINE4  ;判斷是否為第三行
  684.           MOV  A,#88H       ;設(shè)置 LCD 的第三行地址
  685.           CALL  WCOM        ;寫入命令
  686.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  687.           MOV  A,#88H       ;設(shè)置 LCD 的第三行地址
  688.           CALL  WCOM
  689.           JMP  FILL

  691. LINE4:    MOV  A,#98H      ;設(shè)置 LCD 的第四行地址
  692.           CALL  WCOM        ;寫入命令
  693.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  694.           MOV  A,#98H      ;設(shè)置 LCD 的第四行地址
  695.           CALL  WCOM

  697. FILL:     CLR  A            ;填入字符
  698.           MOVC  A,@A+DPTR   ;由信息區(qū)取出字符
  699.           CJNE  A,#0,LC1    ;判斷是否為結(jié)束碼
  700.           RET

  702. LC1:      CALL  WDATA       ;寫入數(shù)據(jù)
  703.           INC  DPTR         ;指針加1
  704.           JMP  FILL         ;繼續(xù)填入字符
  705. ;===============================================
  706. ;清除一行 LCD 的字符
  707. ;輸入一行空格，來替代原顯示字符
  708. ;===============================================
  709. CLR_LINE: MOV  R0,#24       ;清除該行 LCD 的字符
  710. CL1:      MOV  A,#' '
  711.           CALL  WDATA
  712.           DJNZ  R0,CL1
  713.           RET
  714. ;====================================================
  715. ;傳感器 復(fù)位與檢測子程序
  716. ;傳感器 正常 FLAG* 置 1，不正常 FLAG* 置 0。
  717. ;====================================================
  718. RESET:  JNB FLAG0,L31
  719.         SETB CG_CHENEI        ;
  720.         NOP
  721.         CLR CG_CHENEI
  722.         MOV R0,#6BH           ;主機(jī)發(fā)出延時復(fù)位低脈沖
  723.         MOV R1,#04H
  724. TSR11:  DJNZ R0,$             ;延時
  725.         MOV R0,#6BH
  726.         DJNZ R1,TSR11
  727.         SETB CG_CHENEI        ;然后拉高數(shù)據(jù)線
  728.         NOP
  729.         NOP
  730.         NOP
  731.         MOV R0,#32H
  732. TSR21:  JNB CG_CHENEI,TSR31   ;等待傳感器回應(yīng)
  733.         DJNZ R0,TSR21
  734.         JMP TSR41             ; 延時
  735. TSR31:  SETB FLAG4            ; 置標(biāo)志位,表示DS1820存在
  736.         JMP TSR51
  737. TSR41:  CLR FLAG4             ; 清標(biāo)志位,表示DS1820不存在
  738.         JMP TSR61
  739. TSR51:  MOV R0,#06BH
  740.         DJNZ R0,$             ; 時序要求延時一段時間
  741. TSR61:  SETB CG_CHENEI
  742.         RET
  743. ;------------------------
  744. L31:    JNB FLAG1,L32
  745.         SETB CG_CHEWAI        ;
  746.         NOP
  747.         CLR CG_CHEWAI
  748.         MOV R0,#6BH           ;主機(jī)發(fā)出延時復(fù)位低脈沖
  749.         MOV R1,#04H
  750. TSR12:  DJNZ R0,$             ;延時
  751.         MOV R0,#6BH
  752.         DJNZ R1,TSR12
  753.         SETB CG_CHEWAI        ;然后拉高數(shù)據(jù)線
  754.         NOP
  755.         NOP
  756.         NOP
  757.         MOV R0,#32H
  758. TSR22:  JNB CG_CHEWAI,TSR32   ;等待傳感器回應(yīng)
  759.         DJNZ R0,TSR22
  760.         JMP TSR42             ; 延時
  761. TSR32:  SETB FLAG5            ; 置標(biāo)志位,表示DS1820存在
  762.         JMP TSR52
  763. TSR42:  CLR FLAG5             ; 清標(biāo)志位,表示DS1820不存在
  764.         JMP TSR62
  765. TSR52:  MOV R0,#06BH
  766.         DJNZ R0,$             ; 時序要求延時一段時間
  767. TSR62:  SETB CG_CHEWAI
  768.         RET
  769. ;------------------------
  770. L32:    JNB FLAG2,L33
  771.         SETB CG_SHUIWE        ;
  772.         NOP
  773.         CLR CG_SHUIWE
  774.         MOV R0,#6BH           ;主機(jī)發(fā)出延時復(fù)位低脈沖
  775.         MOV R1,#04H
  776. TSR13:  DJNZ R0,$             ;延時
  777.         MOV R0,#6BH
  778.         DJNZ R1,TSR13
  779.         SETB CG_SHUIWE        ;然后拉高數(shù)據(jù)線
  780.         NOP
  781.         NOP
  782.         NOP
  783.         MOV R0,#32H
  784. TSR23:  JNB CG_SHUIWE,TSR33   ;等待傳感器回應(yīng)
  785.         DJNZ R0,TSR23
  786.         JMP TSR43             ; 延時
  787. TSR33:  SETB FLAG6            ; 置標(biāo)志位,表示DS1820存在
  788.         JMP TSR53
  789. TSR43:  CLR FLAG6             ; 清標(biāo)志位,表示DS1820不存在
  790.         JMP TSR63
  791. TSR53:  MOV R0,#06BH
  792.         DJNZ R0,$             ; 時序要求延時一段時間
  793. TSR63:  SETB CG_SHUIWE
  794.         RET
  795. ;------------------------
  796. L33:    JNB FLAG3,L34
  797.         SETB CG_YOUWEN        ;
  798.         NOP
  799.         CLR CG_YOUWEN
  800.         MOV R0,#6BH           ;主機(jī)發(fā)出延時復(fù)位低脈沖
  801.         MOV R1,#04H
  802. TSR14:  DJNZ R0,$             ;延時
  803.         MOV R0,#6BH
  804.         DJNZ R1,TSR14
  805.         SETB CG_YOUWEN        ;然后拉高數(shù)據(jù)線
  806.         NOP
  807.         NOP
  808.         NOP
  809.         MOV R0,#32H
  810. TSR24:  JNB CG_YOUWEN,TSR34   ;等待傳感器回應(yīng)
  811.         DJNZ R0,TSR24
  812.         JMP TSR44             ; 延時
  813. TSR34:  SETB FLAG7            ; 置標(biāo)志位,表示DS1820存在
  814.         JMP TSR54
  815. TSR44:  CLR FLAG7             ; 清標(biāo)志位,表示DS1820不存在
  816.         JMP TSR64
  817. TSR54:  MOV R0,#06BH
  818.         DJNZ R0,$             ; 時序要求延時一段時間
  819. TSR64:  SETB CG_YOUWEN
  820. L34:    RET
  821. ;------------------------

  823. ;==========================================================
  824. ;=================================================
  825. ;對 LCD 做初始化設(shè)置
  826. ;=================================================
  827. SET_LCD:  MOV A,#34H      ;34H--擴(kuò)充指令操作
  828.           CALL  WCOM         ;寫入命令
  829.    MOV A,#30H      ;30H--基本指令操作
  830.           CALL  WCOM         ;寫入命令
  831.    MOV A,#01H      ;清除顯示
  832.           CALL  WCOM         ;寫入命令
  833.           MOV A,#06H      ;指定在資料寫入或讀取時，光標(biāo)的移動方向
  834.           CALL  WCOM         ;DDRAM 的地址計數(shù)器(AC)加1
  835.    MOV A,#0CH      ;開顯示,關(guān)光標(biāo),不閃爍
  836.           CALL  WCOM         ;寫入命令

  838.           RET

  840. ;==================================================
  841. ;===============================================
  842. ;命令寫入子程序
  843. ;RS=L,RW=L,D0-D7=指令碼，E=高脈沖
  844. ;以8位控制方式將命令寫至LCD
  845. ;===============================================
  846. WCOM:    LCALL CHK_BUSY
  847.   CLR LCD_RS
  848.   CLR LCD_RW
  849.   MOV LCD_SJ,A
  850.   SETB LCD_EN
  851.   NOP
  852.   NOP
  853.   CLR LCD_EN
  854.   RET
  855. ;===============================================
  856. ;數(shù)據(jù)寫入子程序
  857. ;RS=H,RW=L,D0-D7=指令碼，E=高脈沖
  858. ;以8位控制方式將數(shù)據(jù)寫至LCD
  859. ;===============================================
  860. WDATA:    MOV  LCD_SJ,A       ;寫入數(shù)據(jù)
  861.           SETB  LCD_RS
  862.           CLR  LCD_RW
  863.           SETB  LCD_EN
  864.           CALL  DE
  865.           CLR  LCD_EN
  866.           CALL  DE
  867.           RET
  868. ;**********************************************************

  870. ;測忙碌子程序
  871. ;RS=0,RW=1,E=H,D0-D7=狀態(tài)字

  873. ;**********************************************************
  874. CHK_BUSY:  MOV LCD_SJ,#0FFH    ;測忙碌子程序
  875.     CLR LCD_RS
  876.     SETB LCD_RW
  877.     SETB LCD_EN
  878.     JB LCD_SJ.7,$
  879.     CLR LCD_EN
  880.     RET

  882. ;====================================================
  883. ;實時溫度值與設(shè)定報警溫度值 TH、TL 比較子程序
  884. ;當(dāng)實際溫度大于 TH 的設(shè)定值時，顯示“過高”并閃動顯示
  885. ;當(dāng)實際溫度小于 TH 的設(shè)定值時，顯示“正常”
  886. ;當(dāng)實際溫度小于 TL 的設(shè)定值時，顯示“過低”
  887. ;====================================================
  888. TEMP_COMP:JNB FLAG2,L101
  889.           MOV TEMP_TH,#SWGWSD
  890.           MOV TEMP_TL,#SWDWSD      ;設(shè)置 LCD 的第一行地址
  891.           SJMP L102
  892. L101:     JNB FLAG3,L103
  893.           MOV TEMP_TH,#YWGWSD
  894.           MOV TEMP_TL,#YWDWSD

  896. L102:     MOV  A,TEMP_ZH
  897.           CJNE  A,TEMP_TH,T_COMP0
  898. T_COMP0:  JNC   CHULI1
  899.           MOV  A,TEMP_ZH
  900.           SUBB  A,TEMP_TL       ;減數(shù)>被減數(shù)，則
  901.           JC  CHULI2            ;借位標(biāo)志位C=1，轉(zhuǎn)

  903.           MOV  DPTR,#BJ50       ;顯示"正常"
  904.           CALL  TEMP_BJ3
  905.           CLR   FLAG1           ;清除報警標(biāo)志
  906. L103:     RET

  908. CHULI1:   MOV  DPTR,#BJ60       ;形成閃爍效果
  909.           CALL  TEMP_BJ3
  910.           MOV  R5,#10           ;延時10MS
  911.           ACALL DELAY1
  912.           MOV  DPTR,#BJ30       ;顯示"過高"
  913.           CALL  TEMP_BJ3
  914.           SETB  FLAG1           ;設(shè)置報警標(biāo)志
  915.           RET

  917. CHULI2:   MOV  DPTR,#BJ40       ;顯示"過低"
  918.           CALL  TEMP_BJ3
  919.           CLR   FLAG1           ;清除報警標(biāo)志
  920.           RET
  921. ;=========================================
  922. ;標(biāo)記字符寫入子程序
  923. ;=========================================
  924. TEMP_BJ3: JNB FLAG2,L001
  925.           MOV  A,#86H       ;設(shè)置 LCD 的第一行地址
  926.           SJMP L002
  927. L001:     JNB FLAG3,L004
  928.           MOV  A,#8EH       ;設(shè)置 LCD 的第三行地址
  929. L002:     CALL  WCOM
  930. L003:     CLR  A            ;填入字符
  931.           MOVC  A,@A+DPTR   ;由信息區(qū)取出字符
  932.           CJNE  A,#0,L005   ;判斷是否為結(jié)束碼
  933. L004:     RET

  935. L005:     CALL  WDATA       ;寫入數(shù)據(jù)
  936.           INC  DPTR         ;指針加1
  937.           JMP  L003         ;繼續(xù)填入字符

  939. BJ30:     DB  "過高",0      ;過高標(biāo)記
  940. BJ40:     DB  "過低",0      ;正常標(biāo)記
  941. BJ50:     DB  "正常",0      ;過低標(biāo)記
  942. BJ60:     DB  "    ",0      ;過低標(biāo)記
  943. ;**********************************************************
  944. ;語音驅(qū)動和播放程序
  945. ;**********************************************************
  946. ;50H為語音段地址暫存器，1到210段，實際用到40
  947. ;50H為E0H～E7H時分別代表自低往高的8級音量
  948. ;在語音播放過程中發(fā)送F2H至50H可循環(huán)播放當(dāng)前地址語音
  949. ;發(fā)送FEH至50H停止播放語音
  950. ;****************************************************
  951. YUYIN: RET        ;$$$$$$$$$$$$$
  952.        MOV TMOD,#00000001B ;定時/計數(shù)器0工作于方式1
  953.        MOV R6,#08H         ;發(fā)碼8位循環(huán)數(shù)據(jù)
  954.        LCALL ONE_LINE      ;調(diào)用一線發(fā)碼子程序
  955.        RET

  957. ONE_LINE:                  ;////一線發(fā)碼子程序
  958.        SETB YYRST          ;復(fù)位
  959.        MOV R7,#2           ;延時2MS
  960.        LCALL DELAY1MS
  961.        CLR YYRST           ;延時使系統(tǒng)穩(wěn)定
  962.        MOV R7,#6           ;延時6MS
  963.        LCALL DELAY1MS
  964.        CLR YYSDA           ;喚醒語音芯片
  965.        MOV R7,#17          ;延時17MS
  966.        LCALL DELAY1MS
  967.        MOV A,YY_DAT

  969. LP1:   SETB YYSDA
  970.        RRC A               ;分辨50H內(nèi)的數(shù)據(jù)各位是高電平還是低電平
  971.        JNC DIDIANPIN       ;高電平用高:低=2:1的脈寬表示
  972.        LCALL DELAY200US
  973.        LCALL DELAY200US
  974.        LCALL DELAY200US
  975.        CLR YYSDA
  976.        LCALL DELAY200US
  977. LP2:   DJNZ R6,LP1         ;查看數(shù)據(jù)是否發(fā)完，未發(fā)完繼續(xù)發(fā)
  978.        MOV R6,#08H
  979.        SETB YYSDA
  980.        RET

  982. DIDIANPIN:                 ;低電平用高:低=1:2的脈寬表示
  983.        LCALL DELAY200US
  984.        CLR YYSDA
  985.        LCALL DELAY200US
  986.        LCALL DELAY200US
  987.        LCALL DELAY200US
  988.        SJMP LP2

  990. ;以下為延時子程序
  991. DELAY200US:                ;延時200US子程序，晶振11.0592MHz，方式1
  992.        MOV  TH0,#0FFH
  993.        MOV  TL0,#47H
  994.        SETB TR0
  995. LOP1:  JBC  TF0,NEXT1
  996.        SJMP LOP1
  997. NEXT1: CLR TR0
  998.        RET

  1000. DELAY1MS:                  ;延時1ms子程序
  1001.        MOV  TH0,#0FCH
  1002.        MOV  TL0,#66H
  1003.        SETB TR0
  1004. LOP2:  JBC  TF0,NEXT2
  1005.        SJMP LOP2
  1006. NEXT2: DJNZ R7,DELAY1MS
  1007.        CLR TR0
  1008.        RET
  1009. ;**********************************************************
  1010. ;延時子程序
  1011. ;**********************************************************
  1012. DE:       MOV  R7,#250        ;延時 500 微秒
  1013.           DJNZ  R7,$
  1014.           RET
  1015. ;===============================================
  1016. DELAY:   MOV  R5,#20      ;延時20MS
  1017. DELAY1:  MOV  R6,#48      ;50
  1018. DL1:     MOV  R7,#96      ;100
  1019.          DJNZ  R7,$
  1020.          DJNZ  R6,DL1
  1021.          DJNZ  R5,DELAY1
  1022.          RET              ;96*2*48*(12/11.0592)+2*(12/11.0592)≈10000uS=10mS

  1024.           END
復(fù)制代碼


回復(fù)

使用道具 舉報

ID:72846 發(fā)表于 2015-1-28 11:46 | 顯示全部樓層
我測試下，感謝分享
回復(fù)

使用道具 舉報

您需要登錄后才可以回帖 登錄 | 立即注冊

本版積分規(guī)則

手機(jī)版|小黑屋|51黑電子論壇 |51黑電子論壇6群 QQ 管理員QQ:125739409;技術(shù)交流QQ群281945664

Powered by 單片機(jī)教程網(wǎng)

快速回復(fù) 返回頂部 返回列表
主站蜘蛛池模板： 男人天堂网址 | 超碰在线人人 | 天天操天天射综合 | 奇米四色在线观看 | h视频免费在线观看 | 欧美久久精品一级黑人c片 91免费在线视频 | 激情毛片 | 国产精品视频在线播放 | 久久久久精 | av网站免费看 | 日韩激情在线 | 中文字幕精品一区二区三区精品 | 国产精品小视频在线观看 | 性一爱一乱一交一视频 | 亚洲 欧美 激情 另类 校园 | 免费av手机在线观看 | 亚洲狠狠 | 91精品麻豆日日躁夜夜躁 | 日本精品久久 | 久久激情五月丁香伊人 | 精品一区二区在线看 | 久久精品久久精品 | 免费国产一区二区视频 | 人人射人人| 男女免费观看在线爽爽爽视频 | 91视频88av| 最新中文字幕 | 亚洲社区在线 | 国产精品久久久久久久久久不蜜臀 | 精品国产一区二区三区在线观看 | 精品无码久久久久久久动漫 | 一级a性色生活片久久毛片 一级特黄a大片 | 日韩毛片在线观看 | av中文字幕在线观看 | 国产精品3区 | 国产精品www| 国产精品成人免费 | 欧美色影院 | 亚洲国产一区在线 | 久久99精品久久久 | 国产精品一区二 |