DS3231匯編程序

ID:261025 · 發表于 2023-10-23 17:37

忘了程序在哪找的程序可以正常使用

            ADDRESS EQU  2EH;

               SCL BIT P3.6;                DS3231 16腳
                                 SDA BIT P3.7;                DS3231 15腳

            ;    30H ; 秒       #00H
                              ;    31H ; 分 #01H
                              ;    32H ; 時 #02H
                              ;    33H ; 周 #03H
                              ;    34H ; 日 #04H
                              ;    35H ; 月 #05H
                              ;    36H ; 年 #06H


;寫入時間日期把30H到36H內的數據寫入到DS3231
                        LCALL SHEZHI_3231;

;讀時間日期把從DS3231讀出的數據存到30H到36H
            LCALL READ_3231;

;=================設置3231功能=================================
;D0H寫入，D1H讀出
;==============================================================
//設置時間
SHEZHI_3231:
      MOV R6,#0D0H       ;寫入數據識別碼
      MOV R0,#30H       ;R0作為間接尋址       存放預設時間
      MOV ADDRESS,#00H;開始寫入地址從秒開始
      MOV R5,#7
      LCALL  WRITE
      RET
//寫入時間
WRITE:
      LCALL  START
      MOV A,R6
      LCALL  SENDA
      LCALL  ACK
      JC WRITE
      MOV A,ADDRESS
      LCALL  SENDA
      LCALL  ACK
      MOV A,@R0
      LCALL  SENDA
      LCALL  ACK
      LCALL  STOP
      INC R0
      INC ADDRESS
      DJNZ R5,WRITE ;減1后不為0轉移，存儲6位
      RET
;=================3231讀程序==============================
READ_3231:
         MOV R0,#30H;                      ;R0開始存放地址
      MOV ADDRESS,#00H;       ;指向地址秒
      MOV R5,#7;          讀七位讀到年
SS:    MOV R2,#0D0H;       3231ID識別
      MOV R4,#0D1H;       讀3231
      LCALL READ       ;調用讀存儲器程序
      INC ADDRESS
      INC R0
      DJNZ R5,SS
//溫度
/*    MOV R0,#38H                      ;R0開始存放地址
      MOV ADDRESS,#11H       ;指向溫度地址
      MOV R2,       #0D0H;3231ID識別
      MOV R4,       #0D1H;讀3231
      LCALL  READ             ;調用讀存儲器程序       */
      RET

;----------------------------------
READ:       LCALL START             ;啟動總線
      MOV A,R2       ;發送芯片識別碼
      LCALL SENDA
      LCALL ACK             ; 芯片應答
      JC READ             ;

      MOV A,ADDRESS
      LCALL SENDA
      LCALL ACK

READ_A:       LCALL START
      MOV A,R4
      LCALL SENDA
      LCALL ACK
      JC READ_A

RECE: LCALL RECEIVE
      MOV @R0,A       ;讀到數據存儲到@R0指定地址
      LCALL ACK
      LCALL STOP
      RET
;-------總線啟動程序---------
START:  SETB SCL
      SETB SDA
      NOP
      NOP
      CLR SDA
      NOP
      NOP
      CLR SCL
      RET
;-------總線停止程序---------
STOP: CLR SDA
      NOP
      NOP
      SETB SCL
      NOP
      NOP
      SETB SDA
      RET
;-----------應答----------
ACK: SETB SDA
      NOP
      NOP
      SETB SCL
      JB SDA,ACK_0
      CLR C
      SJMP ACK_1

ACK_0:  SETB C
ACK_1:  NOP
      NOP
      CLR SCL
      RET
;--------------發送8位數據---------
SENDA:  MOV B,#08H
SEND_1: RlC A
      MOV SDA,C
      SETB SCL
      NOP
      NOP
      CLR SCL
      DJNZ B,SEND_1
      RET
;--------------接收8位數據-----------
RECEIVE: MOV B,#08H
         CLR A
         SETB SDA
RECEIVE_1:  SETB SCL
         NOP
         NOP
         MOV C,SDA
         RlC A
         CLR SCL
         DJNZ B,RECEIVE_1
         RET