求大佬告知怎么把共陽(yáng)極數(shù)碼管秒表匯編語(yǔ)言程序改成共陰極匯編語(yǔ)言，改哪些地方，...

ID:535873 · 發(fā)表于 2019-5-14 23:58

本帖最后由 yulexuan2019 于 2019-5-15 00:42 編輯

求大佬幫忙改下程序，把2個(gè)一位共陽(yáng)極數(shù)碼管秒表程序改成共陰極匯編語(yǔ)言程序，求教，實(shí)在不知道改哪里，改了半天也不對(duì)，求詳細(xì)更改地方！程序功能是00-99秒表，怎么改成共陰極的。圖上上面第一個(gè)按鍵控制開(kāi)始暫停，第二個(gè)按鍵控制清零！
仿真圖和程序如下：

ORG  0000H
      AJMP MAIN
      ORG  0003H
      AJMP X0_INT
      ORG  000BH
      AJMP T0_INT
      ORG  0013H
      AJMP X1_INT
MAIN:
      MOV  TMOD,#01H          ;T0定時(shí)方式1
      MOV  TH0, #(65536-50000) / 256 ;50ms@12MHz
      MOV  TL0, #(65536-50000) MOD 256;
      SETB TR0
      SETB ET0                ;開(kāi)啟定時(shí)中斷
      SETB EX0
      SETB EX1
      SETB EA                ;定時(shí)器初始化結(jié)束，下面循環(huán)顯示即可
      MOV  R1, #99H          ;0~99計(jì)數(shù).
      MOV  R7, #1             ;50ms計(jì)數(shù).
      MOV  P0, #0C0H
      MOV  P2, #0C0H
LOOP:
      SJMP LOOP
;-----------------------------------------------------------
DELAY:                         ;延時(shí)子程序.
AA4: MOV  R4,  #0
      DJNZ R4,  $
      DJNZ R4,  $
      RET
;-----------------------------------------------------------
X0_INT:                         ;啟動(dòng)/停止
      CPL  F0
      RETI
;-----------------------------------------------------------
X1_INT:                         ;清零
      MOV  R1, #0
      MOV  P0, #0C0H
      MOV  P2, #0C0H
      RETI
;-----------------------------------------------------------
T0_INT:                         ;50ms中斷執(zhí)行一次.
      MOV TL0, #(65536-50000) MOD 256;
      MOV TH0, #(65536-50000) / 256 ;50ms@12MHz
      DJNZ R7, T0_END       ;中斷不到20次.
      MOV  R7, #20
      JNB  F0, T0_END
      MOV  A,  R1
      ADD  A,  #1
      DA A
      MOV  R1, A
      ANL  A,  #0FH
      MOV  DPTR, #TAB
      MOVC A, @A+DPTR       ;查出段碼
      MOV  P2, A
      MOV  A,  R1
      SWAP A
      ANL  A,  #0FH
      MOVC A, @A+DPTR       ;查出段碼
      MOV  P0, A             ;顯示十位數(shù).
T0_END:
      RETI
;-----------------------------------------------------------
TAB:
      DB 0c0H,0f9H,0a4H,0b0H,99H,92H,82H,0f8H,80H, 90H
      END

ID:535873 · 發(fā)表于 2019-5-15 11:05

STM32指下有亁坤發(fā)表于 2019-5-15 00:39
@A+DPTR ;查出段碼這里能不能將取的值取反，如果是C語(yǔ)言編的，就是在這個(gè)地方取一下反就好了，另外位碼 ...

能給出具體更改嗎？

ID:537018 · 發(fā)表于 2019-5-16 18:18

把段碼取反就可以

ID:149144 · 發(fā)表于 2019-5-16 22:14

數(shù)碼管先換成共陰的，當(dāng)然公共端要接地。其次是程序，改一下這個(gè)就行啦
TAB:
//DB 0c0H,0f9H,0a4H,0b0H,99H,92H,82H,0f8H,80H, 90H
DB 0x3f,0x06,0x5b,0x4f,0x66,0x6d,0x7d,0x07,0x7f,0x6f
END

看附件吧

ID:155507 · 發(fā)表于 2019-5-16 23:14

   MOV  DPTR, #TAB
      MOVC A, @A+DPTR       ;查出段碼
      CPL A  ;段碼取反
      MOV  P2, A

帳號(hào)		自動(dòng)登錄	找回密碼
密碼			立即注冊(cè)

久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

求大佬告知怎么把共陽(yáng)極數(shù)碼管秒表匯編語(yǔ)言程序改成共陰極匯編語(yǔ)言，改哪些地方，...