【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）

ID:513258 · 發表于 2019-8-30 19:15

RC522模塊各引腳功能
  SDA -- 串行數據線（IIC接口時的I/O線）；在SPI接口中為NSS（從機標志管腳）；
  SCK -- 連接MCU的SCK信號；
MOSI -- MCU輸出，RC522接收（即主設備輸出，從設備輸入）；
MISO -- RC522輸出，MCU接收（即從設備輸出，主設備輸入）；
  IRQ -- 中斷請求輸出；
GND -- 接地；
  RST -- 復位；
3.3V -- VSS，工作電壓，若使用的事5V的MCU，注意分壓。

ID:513258 · 發表于 2019-8-30 20:36

ID:513258 · 發表于 2019-8-30 21:04

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零二：MFRC-522 RFID射頻 IC卡感應模塊讀卡器S50復旦卡鑰匙扣
1、工具-管理庫-搜索“MFRC522”庫-安裝
2、項目：使用MFRC522 RFID和Arduino讀寫標簽
3、RFID與Arduino Uno的連線
SDA------------------------Digital 10
SCK------------------------Digital 13
MOSI----------------------Digital 11
MISO----------------------Digital 12
IRQ------------------------不用連接
GND-----------------------GND
RST------------------------Digital 9
3.3V------------------------3.3V (千萬不要連接到5V接口！！！)
*/
#include <SPI.h>
#include <MFRC522.h>
#define SS_PIN 10
#define RST_PIN 9
MFRC522 mfrc522(SS_PIN, RST_PIN); // Create MFRC522 instance.
void setup() {
Serial.begin(9600); // Initialize serial communications with the PC
SPI.begin(); // Init SPI bus
mfrc522.PCD_Init(); // Init MFRC522 card
Serial.println("Scan PICC to see UID and type...");
}
void loop() {
// Look for new cards
if ( ! mfrc522.PICC_IsNewCardPresent()) {
return;
}
// Select one of the cards
if ( ! mfrc522.PICC_ReadCardSerial()) {
return;
}
// Dump debug info about the card. PICC_HaltA() is automatically called.
mfrc522.PICC_DumpToSerial(&(mfrc522.uid));
}

復制代碼

ID:513258 · 發表于 2019-8-30 21:07

ID:513258 · 發表于 2019-8-30 21:20

ID:513258 · 發表于 2019-8-31 07:39

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零二：MFRC-522 RFID射頻 IC卡感應模塊讀卡器S50復旦卡鑰匙扣
1、工具-管理庫-搜索“MFRC522”庫-安裝
2、項目二：讀取UID，并將其分別以十進制和十六進制輸出到串口
3、RFID與Arduino Uno的連線
SDA------------------------Digital 10
SCK------------------------Digital 13
MOSI----------------------Digital 11
MISO----------------------Digital 12
IRQ------------------------不用連接
GND-----------------------GND
RST------------------------Digital 9
3.3V------------------------3.3V (千萬不要連接到5V接口！！！)
*/
#include <SPI.h>
#include <MFRC522.h>
#define SS_PIN 10
#define RST_PIN 9
MFRC522 rfid(SS_PIN, RST_PIN); //實例化類
// 初始化數組用于存儲讀取到的NUID
byte nuidPICC[4];
void setup() {
Serial.begin(9600);
SPI.begin(); // 初始化SPI總線
rfid.PCD_Init(); // 初始化 MFRC522
}
void loop() {
// 找卡
if ( ! rfid.PICC_IsNewCardPresent())
return;
// 驗證NUID是否可讀
if ( ! rfid.PICC_ReadCardSerial())
return;
MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
// 檢查是否MIFARE卡類型
if (piccType != MFRC522::PICC_TYPE_MIFARE_MINI &&
piccType != MFRC522::PICC_TYPE_MIFARE_1K &&
piccType != MFRC522::PICC_TYPE_MIFARE_4K) {
Serial.println("不支持讀取此卡類型");
return;
}
// 將NUID保存到nuidPICC數組
for (byte i = 0; i < 4; i++) {
nuidPICC[i] = rfid.uid.uidByte[i];
}
Serial.print("十六進制UID：");
printHex(rfid.uid.uidByte, rfid.uid.size);
Serial.println();
Serial.print("十進制UID：");
printDec(rfid.uid.uidByte, rfid.uid.size);
Serial.println();
// 使放置在讀卡區的IC卡進入休眠狀態，不再重復讀卡
rfid.PICC_HaltA();
// 停止讀卡模塊編碼
rfid.PCD_StopCrypto1();
}
void printHex(byte *buffer, byte bufferSize) {
for (byte i = 0; i < bufferSize; i++) {
Serial.print(buffer[i] < 0x10 ? " 0" : "");
Serial.print(buffer[i], HEX);
}
}
void printDec(byte *buffer, byte bufferSize) {
for (byte i = 0; i < bufferSize; i++) {
Serial.print(buffer[i] < 0x10 ? " 0" : "");
Serial.print(buffer[i], DEC);
}
}

復制代碼

ID:513258 · 發表于 2019-8-31 07:44

ID:513258 · 發表于 2019-8-31 08:10

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零二：MFRC-522 RFID射頻 IC卡感應模塊讀卡器S50復旦卡鑰匙扣
1、安裝庫：IDE-工具-管理庫-搜索“MFRC522”庫-安裝
2、項目三：RC522 模塊的讀寫操作
3、RFID與Arduino Uno的連線
SDA------------------------Digital 10
SCK------------------------Digital 13
MOSI----------------------Digital 11
MISO----------------------Digital 12
IRQ------------------------不用連接
GND-----------------------GND
RST------------------------Digital 9
3.3V------------------------3.3V (千萬不要連接到5V接口！！！)
*/
#include <SPI.h>
#include <MFRC522.h>
#define RST_PIN 9 // 配置針腳
#define SS_PIN 10
MFRC522 mfrc522(SS_PIN, RST_PIN); // 創建新的RFID實例
MFRC522::MIFARE_Key key;
void setup() {
Serial.begin(9600); // 設置串口波特率為9600
while (!Serial); // 如果串口沒有打開，則死循環下去不進行下面的操作
SPI.begin(); // SPI開始
mfrc522.PCD_Init(); // Init MFRC522 card
for (byte i = 0; i < 6; i++) {
key.keyByte[i] = 0xFF;
}
Serial.println(F("掃描卡開始進行讀或者寫"));
Serial.print(F("使用A和B作為鍵"));
dump_byte_array(key.keyByte, MFRC522::MF_KEY_SIZE);
Serial.println();
Serial.println(F("注意，會把數據寫入到卡在#1"));
}
void loop() {
// 尋找新卡
if ( ! mfrc522.PICC_IsNewCardPresent())
return;
// 選擇一張卡
if ( ! mfrc522.PICC_ReadCardSerial())
return;
// 顯示卡片的詳細信息
Serial.print(F("卡片 UID:"));
dump_byte_array(mfrc522.uid.uidByte, mfrc522.uid.size);
Serial.println();
Serial.print(F("卡片類型: "));
MFRC522::PICC_Type piccType = mfrc522.PICC_GetType(mfrc522.uid.sak);
Serial.println(mfrc522.PICC_GetTypeName(piccType));
// 檢查兼容性
if ( piccType != MFRC522::PICC_TYPE_MIFARE_MINI
&& piccType != MFRC522::PICC_TYPE_MIFARE_1K
&& piccType != MFRC522::PICC_TYPE_MIFARE_4K) {
Serial.println(F("僅僅適合Mifare Classic卡的讀寫"));
return;
}
// 我們只使用第二個扇區
// 覆蓋扇區4
byte sector = 1;
byte blockAddr = 4;
byte dataBlock[] = {
0x01, 0x02, 0x03, 0x04, // 1, 2, 3, 4,
0x05, 0x06, 0x07, 0x08, // 5, 6, 7, 8,
0x00, 0x00, 0x00, 0x00, // 0，0，0，0
0x00, 0x00, 0x00, 0x00 // 0，0，0，0
};//寫入的數據定義
byte trailerBlock = 7;
MFRC522::StatusCode status;
byte buffer[18];
byte size = sizeof(buffer);
// 原來的數據
Serial.println(F("顯示原本的數據..."));
status = (MFRC522::StatusCode) mfrc522.PCD_Authenticate(MFRC522::PICC_CMD_MF_AUTH_KEY_A, trailerBlock, &key, &(mfrc522.uid));
if (status != MFRC522::STATUS_OK) {
Serial.print(F("身份驗證失敗？或者是卡鏈接失敗"));
Serial.println(mfrc522.GetStatusCodeName(status));
return;
}
// 顯示整個扇區
Serial.println(F("顯示所有扇區的數據"));
mfrc522.PICC_DumpMifareClassicSectorToSerial(&(mfrc522.uid), &key, sector);
Serial.println();
// 從塊兒讀取數據
Serial.print(F("讀取塊兒的數據在：")); Serial.print(blockAddr);
Serial.println(F("塊 ..."));
status = (MFRC522::StatusCode) mfrc522.MIFARE_Read(blockAddr, buffer, &size);
if (status != MFRC522::STATUS_OK) {
Serial.print(F("讀卡失敗，沒有連接上 "));
Serial.println(mfrc522.GetStatusCodeName(status));
}
Serial.print(F("數據內容在第 ")); Serial.print(blockAddr); Serial.println(F(" 塊:"));
dump_byte_array(buffer, 16); Serial.println();
Serial.println();
//開始進行寫入準備
Serial.println(F("開始進行寫入的準備..."));
status = (MFRC522::StatusCode) mfrc522.PCD_Authenticate(MFRC522::PICC_CMD_MF_AUTH_KEY_B, trailerBlock, &key, &(mfrc522.uid));
if (status != MFRC522::STATUS_OK) {
Serial.print(F("寫入失敗，沒有連接上或者沒有權限 "));
Serial.println(mfrc522.GetStatusCodeName(status));
return;
}
// Write data to the block
Serial.print(F("在第： ")); Serial.print(blockAddr);
Serial.println(F(" 塊中寫入數據..."));
dump_byte_array(dataBlock, 16); Serial.println();
status = (MFRC522::StatusCode) mfrc522.MIFARE_Write(blockAddr, dataBlock, 16);
if (status != MFRC522::STATUS_OK) {
Serial.print(F("寫入失敗... "));
Serial.println(mfrc522.GetStatusCodeName(status));
}
Serial.println();
// 再次讀取卡中數據，這次是寫入之后的數據
Serial.print(F("讀取寫入后第")); Serial.print(blockAddr);
Serial.println(F(" 塊的數據 ..."));
status = (MFRC522::StatusCode) mfrc522.MIFARE_Read(blockAddr, buffer, &size);
if (status != MFRC522::STATUS_OK) {
Serial.print(F("讀取失敗... "));
Serial.println(mfrc522.GetStatusCodeName(status));
}
Serial.print(F("塊 ")); Serial.print(blockAddr); Serial.println(F("數據為 :"));
dump_byte_array(buffer, 16); Serial.println();
// 驗證一下數據，要保證寫入前后數據是相等的
// 通過計算塊中的字節數量
Serial.println(F("等待驗證結果..."));
byte count = 0;
for (byte i = 0; i < 16; i++) {
// 比較一下緩存中的數據（我們讀出來的數據） = （我們剛剛寫的數據）
if (buffer[i] == dataBlock[i])
count++;
}
Serial.print(F("匹配的字節數量 = ")); Serial.println(count);
if (count == 16) {
Serial.println(F("驗證成功 :"));
} else {
Serial.println(F("失敗，數據不匹配"));
Serial.println(F("也許寫入的內容不恰當"));
}
Serial.println();
// 轉儲扇區數據
Serial.println(F("寫入后的數據內容為：:"));
mfrc522.PICC_DumpMifareClassicSectorToSerial(&(mfrc522.uid), &key, sector);
Serial.println();
// 停止 PICC
mfrc522.PICC_HaltA();
//停止加密PCD
mfrc522.PCD_StopCrypto1();
}
/**
* 將字節數組轉儲為串行的十六進制值
*/
void dump_byte_array(byte *buffer, byte bufferSize) {
for (byte i = 0; i < bufferSize; i++) {
Serial.print(buffer[i] < 0x10 ? " 0" : " ");
Serial.print(buffer[i], HEX);
}
}

復制代碼

ID:513258 · 發表于 2019-8-31 08:14

ID:513258 · 發表于 2019-8-31 11:42

ID:513258 · 發表于 2019-8-31 11:48

ID:513258 · 發表于 2019-8-31 11:49

ID:513258 · 發表于 2019-8-31 11:51

ID:513258 · 發表于 2019-8-31 11:55

ID:513258 · 發表于 2019-8-31 11:58

ID:513258 · 發表于 2019-8-31 12:04

ID:513258 · 發表于 2019-8-31 12:06

ID:513258 · 發表于 2019-8-31 12:12

ID:513258 · 發表于 2019-8-31 13:04

NFC Tools PRO
應該是目前為止最強大的NFC工具了吧（APP），可惜nfc這玩意兒不是所有手機都標配。NFC Tools PRO是一款可以讀取和寫入nfc標簽的工具，同時還提供了一些額外功能。NFC工具專業版包含額外的功能，如配置文件管理等等。保存您的標記或任務配置文件后重新使用它們。NFC工具專業版允許您在記錄或任務直接從現有的NFC標簽導入。您可以非常快的編輯您的標簽。您也可以直接運行的任務配置文件。

主要功能：
- 讀寫NFC
- NFC標簽配置文件管理
- 從標簽導入任務

ID:513258 · 發表于 2019-8-31 13:10

用華為P10手機讀取手頭的IC卡和鑰匙扣相關數據

ID:513258 · 發表于 2019-8-31 13:12

ID:513258 · 發表于 2019-8-31 14:23

37款傳感器與模塊的提法，在網絡上廣泛流傳，其實Arduino能夠兼容的傳感器模塊肯定是不止37種的。鑒于本人手頭積累了一些傳感器和模塊，依照實踐出真知（一定要動手做）的理念，以學習和交流為目的，這里準備逐一動手試試做實驗，不管成功與否，都會記錄下來---小小的進步或是搞不定的問題，希望能夠拋磚引玉。

【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零三： 8X32 LED點陣顯示模塊 MAX7219 輸出共陰 5V 模組

0.jpg (136.24 KB, 下載次數: 562)

下載附件

2019-8-31 14:23 上傳

ID:513258 · 發表于 2019-8-31 14:36

MAX7219
是美國MAXIM 公司推出的多位LED 顯示驅動器，采用3 線串行接口傳送數據，可直接與單片機接口連接，用戶能方便修改其內部參數，以實現多位LED 顯示。它內含硬件動態掃描電路、BCD譯碼器、段驅動器和位驅動器。此外，其內部還含有8X8 位靜態RAM,用于存放8 個數字的顯示數據。顯然，它可直接驅動64 段LED點陣顯示器。當多片MAX7219 級聯時，可控制更多的LED 點陣顯示器。顯示的數據通過單片機數據處理后，送給MAX7219 顯示。

MAX7219/MAX7221是一種集成化的串行輸入/輸出共陰極顯示驅動器,它連接微處理器與8位數字的7段數字LED顯示，也可以連接條線圖顯示器或者64個獨立的LED。其上包括一個片上的B型BCD編碼器、多路掃描回路，段字驅動器，而且還有一個8*8的靜態RAM用來存儲每一個數據。只有一個外部寄存器用來設置各個LED的段電流。MAX7221與SPI™、QSPI™以及 MICROWIRE™相兼容，同時它有限制回轉電流的段驅動來減少EMI（電磁干擾）。一個方便的四線串行接口可以聯接所有通用的微處理器。每個數據可以尋址在更新時不需要改寫所有的顯示。MAX7219/MAX7221同樣允許用戶對每一個數據選擇編碼或者不編碼。整個設備包含一個150μA的低功耗關閉模式，模擬和數字亮度控制，一個掃描限制寄存器允許用戶顯示1-8位數據，還有一個讓所有LED發光的檢測模式。

ID:513258 · 發表于 2019-8-31 15:55

管腳描述
1 DIN 串行數據輸入端口。在時鐘上升沿時數據被載入內部的16位寄存器。
2,3,5-8,10,11 DIG 0–DIG7 八個數據驅動線路置顯示器共陰極為低電平。關閉時7219此管腳輸出高電平，7221呈現高阻抗。
4,9 GND 地線（4腳和9腳必須同時接地）
12 LOAD (MAX7219) 載入數據。連續數據的后16位在LOAD端的上升沿時被鎖定。CS (MAX7221) 片選端。該端為低電平時串行數據被載入移位寄存器。連續數據的后
16位在cs端的上升沿時被鎖定。
13 CLK 時鐘序列輸入端。最大速率為 10MHz.在時鐘的上升沿，數據移入內部移位寄存器。下降沿時，數據從DOUT端輸出。對MAX7221來說，只有當cs端為低電平時時鐘輸入才有效。
14-17,20-23 SEG 7 段和小數點驅動，為顯示器提供電流。當一個段驅A–SEG G, 動關閉時，7219的此端呈低電平，7221呈現高阻抗。DP
18 SET 通過一個電阻連接到VDD 來提高段電流。
19 V+ 正極電壓輸入，+5V
24 DOUT 串行數據輸出端口，從DIN輸入的數據在16.5個時鐘周期后在此端有效。當使用多個MAX7219/MAX7221時用此端方便擴展。

ID:513258 · 發表于 2019-8-31 16:11

功能特點
1 10MHz連續串行口
2 獨立的LED段控制
3 數字的譯碼與非譯碼選擇
4 150μA的低功耗關閉模式
5 亮度的數字和模擬控制
6 高電壓中斷顯示
7 共陰極LED顯示驅動
8 限制回轉電流的段驅動來減少EMI（MAX7221）
9 SPI, QSPI, MICROWIRE串行接口（MAX7221）
10 24腳的 DIP和 SO 封裝

ID:513258 · 發表于 2019-8-31 16:46

8X32 LED點陣顯示級聯模塊，MAX7219是一種集成化的串行輸入/輸出共陰極顯示驅動器,它連接微處理器與8位數字的7段數字LED顯示，也可以連接條線圖顯示器或者64個獨立的LED。其上包括一個片上的B型BCD編碼器、多路掃描回路，段字驅動器，而且還有一個8*8的靜態RAM用來存儲每一個數據。只有一個外部寄存器用來設置各個LED的段電流。一個方便的四線串行接口可以聯接所有通用的微處理器。每個數據可以尋址在更新時不需要改寫所有的顯示。MAX7219同樣允許用戶對每一個數據選擇編碼或者不編碼。整個設備包含一個150μA的低功耗關閉模式，模擬和數字亮度控制，一個掃描限制寄存器允許用戶顯示1-8位數據，還有一個讓所有LED發光的檢測模式。只需要3個IO口即可驅動1個點陣！點陣顯示時無閃爍！支持級聯！

ID:513258 · 發表于 2019-9-2 12:01

ID:513258 · 發表于 2019-9-2 12:27

ID:513258 · 發表于 2019-9-2 12:30

ID:513258 · 發表于 2019-9-2 12:32

模塊參數：
1.單個模塊可以驅動一個8*8共陰點陣
2.模塊工作電壓：5V
3.模塊尺寸：長12.8厘米X寬3.2厘米X高1.3厘米
4.帶64個固定螺絲孔，孔徑3mm
5.模塊帶輸入輸出接口，支持多個模塊級聯

接線說明：
1.模塊左邊為輸入端口，右邊為輸出端口。
2.控制單個模塊時，只需要將輸入端口接到CPU
3.多個模塊級聯時，第1個模塊的輸入端接CPU，輸出端接第2個模塊的輸入端，第2個模塊的輸出端接第3個模塊的輸入端，以此類推...

ID:513258 · 發表于 2019-9-2 12:38

ID:513258 · 發表于 2019-9-2 12:39

ID:513258 · 發表于 2019-9-2 12:40

ID:513258 · 發表于 2019-9-2 12:47

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零三： 8X32 LED點陣顯示級聯模塊 MAX7219 輸出共陰 5V 模組
1、下載安裝庫：
GitHub | riyas-org/max7219 https://github.com/riyas-org/max7219
2、項目：應用多種函數，顯示字母，笑臉等圖案以及左向移動
3、連線：
VCC → 5V
GND → GND
DIN → D11
CS → D12
CLK → D13
*/
#include <MaxMatrix.h>
int DIN = 11; // DIN pin of MAX7219 module
int CLK = 13; // CLK pin of MAX7219 module
int CS = 12; // CS pin of MAX7219 module
int maxInUse = 1;
MaxMatrix m(DIN, CS, CLK, maxInUse);
char A[] = {4, 8,
B01111110,
B00010001,
B00010001,
B01111110,
};
char B[] = {4, 8,
B01111111,
B01001001,
B01001001,
B00110110,
};
char smile01[] = {8, 8,
B00111100,
B01000010,
B10010101,
B10100001,
B10100001,
B10010101,
B01000010,
B00111100
};
char smile02[] = {8, 8,
B00111100,
B01000010,
B10010101,
B10010001,
B10010001,
B10010101,
B01000010,
B00111100
};
char smile03[] = {8, 8,
B00111100,
B01000010,
B10100101,
B10010001,
B10010001,
B10100101,
B01000010,
B00111100
};
void setup() {
m.init(); // MAX7219 initialization
m.setIntensity(8); // initial led matrix intensity, 0-15
}
void loop() {
// Seting the LEDs On or Off at x,y or row,column position
m.setDot(6,2,true);
delay(1000);
m.setDot(6,3,true);
delay(1000);
m.clear(); // Clears the display
for (int i=0; i<8; i++){
m.setDot(i,i,true);
delay(300);
}
m.clear();
// Displaying the character at x,y (upper left corner of the character)
m.writeSprite(2, 0, A);
delay(1000);
m.writeSprite(2, 0, B);
delay(1000);
m.writeSprite(0, 0, smile01);
delay(1000);
m.writeSprite(0, 0, smile02);
delay(1000);
m.writeSprite(0, 0, smile03);
delay(1000);
for (int i=0; i<8; i++){
m.shiftLeft(false,false);
delay(300);
}
m.clear();
}

復制代碼

ID:513258 · 發表于 2019-9-2 14:57

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零三： 8X32 LED點陣顯示級聯模塊 MAX7219 輸出共陰 5V 模組
1、下載安裝庫：
GitHub | riyas-org/max7219 https://github.com/riyas-org/max7219
2、項目：程序中將所要顯示的圖型使用數組方式存放，主回圈中交錯顯示在 8x8 點陣
模塊上產生一個有趣的點陣動畫
3、連線：
VCC → 5V
GND → GND
DIN 接 D11 (MOSI)
CS 接 D10 (SS)
CLK 接 D13 (SCK)
*/
#include <SPI.h>
const byte sprite[2][8] = {
{ 0xf8, 0xbc, 0x15, 0x7e, 0x7e, 0x15, 0xbc, 0xf8 },
{ 0xfc, 0x8e, 0x1b, 0x2e, 0x2e, 0x1b, 0x8e, 0xfc }
};
const byte DECODEMODE = 0x09;
const byte INTENSITY = 0x0a;
const byte SCANLIMIT = 0x0b;
const byte SHUTDOWN = 0x0c;
const byte DISPLAYTEST = 0x0f;
void max7219(const byte reg, const byte data) {
digitalWrite(SS, LOW);
SPI.transfer(reg);
SPI.transfer(data);
digitalWrite(SS, HIGH);
}
void setup() {
SPI.begin();
max7219(SCANLIMIT, 7);
max7219(DECODEMODE, 0);
max7219(INTENSITY, 2);
max7219(DISPLAYTEST, 0);
max7219(SHUTDOWN, 1);
for(byte i=0; i<8; i++) {
max7219(i+1, 0);
}
}
void loop() {
for(byte j=0; j<2; j++) {
for(byte i=0; i<8; i++) {
max7219(i+1, sprite[j][i]);
}
delay(500);
}
}

復制代碼

ID:513258 · 發表于 2019-9-2 15:32

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零三： 8X32 LED點陣顯示級聯模塊 MAX7219 輸出共陰 5V 模組
1、下載庫 https://www.pjrc.com/teensy/arduino_libraries/Matrix_Sprite.zip
2、項目：在四個8x8屏間跳動的紅點
3、連線：
VCC → 5V
GND → GND
DIN 接 D11 (MOSI)
CS 接 D10 (SS)
CLK 接 D13 (SCK)
*/
#include <Sprite.h> // Sprite before Matrix
#include <Matrix.h>
const int numChips = 4;
//DIN, CLK, SS, #chips
Matrix myLeds = Matrix(11, 13, 10, numChips);
void setup() {
myLeds.clear();
}
void loop() {
byte x, y;
// light one LED at a time, scanning left to right
// and top to bottom... useful for testing the matrix
for (y=0; y<8; y++) {
for (x=0; x<(numChips * 8); x++) {
myLeds.write(x, y, HIGH);
delay(20);
myLeds.write(x, y, LOW);
}
}
}

復制代碼

ID:513258 · 發表于 2019-9-2 16:14

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零三： 8X32 LED點陣顯示級聯模塊 MAX7219 輸出共陰 5V 模組
1、下載庫 https://www.pjrc.com/teensy/arduino_libraries/Matrix_Sprite.zip
2、項目：顯示字母
3、連線：
VCC → 5V
GND → GND
DIN 接 D11 (MOSI)
CS 接 D10 (SS)
CLK 接 D13 (SCK)
*/
#include <Sprite.h> // Sprite before Matrix
#include <Matrix.h>
//DIN, CLK, CS, #chips
Matrix myLeds = Matrix(11, 13, 10, 3);
Sprite letter_L = Sprite(5, 8,
B11000,
B11000,
B11000,
B11000,
B11000,
B11000,
B11111,
B11111
);
Sprite letter_E = Sprite(5, 8,
B11111,
B11111,
B11000,
B11110,
B11110,
B11000,
B11111,
B11111
);
Sprite letter_D = Sprite(6, 8,
B111100,
B111110,
B110111,
B110011,
B110011,
B110111,
B111110,
B111100
);
Sprite letter_S = Sprite(5, 8,
B01110,
B11111,
B11000,
B11110,
B01111,
B00011,
B11111,
B01110
);
void setup() {
myLeds.clear();
myLeds.setBrightness(0);
myLeds.write(3, 0, letter_L);
myLeds.write(10, 0, letter_E);
myLeds.write(18, 0, letter_D);
myLeds.write(26, 0, letter_S);
}
void loop() {
}

復制代碼

ID:513258 · 發表于 2019-9-2 16:17

ID:513258 · 發表于 2019-9-2 16:24

Matrix庫的幾個函數

基本用法，僅限像素
Matrix myLeds = Matrix（DIN，CLK，LOAD，numChips）;
使用您選擇的名稱創建Matrix對象的實例。DIN，CLK和LOAD是連接這些信號的引腳號。如果連接了多個單獨連接的MAX7219芯片，則可以創建多個對象。

myLeds。clear（）;
清除整個顯示屏。

myLeds。setBrightness（15）;
設置顯示亮度，從0到15（最亮）。

myLeds。write（x，y，value）;
更改單個像素。對于關閉，值應為LOW，對于on，值應為HIGH。

基本用法，使用Sprite
Sprite myIcon = Sprite（寬度，高度，B11000，B11000，B11111，B11111）;
創建一個精靈對象。您可以根據需要創建任意數量的精靈，每個精靈都有一個唯一的名稱。寬度應與每個數據值中的位數匹配，高度應與數據值的數量匹配。

myLeds。write（x，y，myIcon）;
在顯示屏上繪制一個閃爍的精靈。

ID:513258 · 發表于 2019-9-2 16:52

/*
【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百零三： 8X32 LED點陣顯示級聯模塊 MAX7219 輸出共陰 5V 模組
1、下載安裝庫：
GitHub | riyas-org/max7219 https://github.com/riyas-org/max7219
2、項目：建立字母庫，立式滾動文本顯示
3、連線：
VCC → 5V
GND → GND
DIN 接 D11 (MOSI)
CS 接 D10 (SS)
CLK 接 D13 (SCK)
*/
#include <MaxMatrix.h>
#include <avr/pgmspace.h>
PROGMEM const unsigned char CH[] = {
3, 8, B00000000, B00000000, B00000000, B00000000, B00000000, // space
1, 8, B01011111, B00000000, B00000000, B00000000, B00000000, // !
3, 8, B00000011, B00000000, B00000011, B00000000, B00000000, // "
5, 8, B00010100, B00111110, B00010100, B00111110, B00010100, // #
4, 8, B00100100, B01101010, B00101011, B00010010, B00000000, // $
5, 8, B01100011, B00010011, B00001000, B01100100, B01100011, // %
5, 8, B00110110, B01001001, B01010110, B00100000, B01010000, // &
1, 8, B00000011, B00000000, B00000000, B00000000, B00000000, // '
3, 8, B00011100, B00100010, B01000001, B00000000, B00000000, // (
3, 8, B01000001, B00100010, B00011100, B00000000, B00000000, // )
5, 8, B00101000, B00011000, B00001110, B00011000, B00101000, // *
5, 8, B00001000, B00001000, B00111110, B00001000, B00001000, // +
2, 8, B10110000, B01110000, B00000000, B00000000, B00000000, // ,
4, 8, B00001000, B00001000, B00001000, B00001000, B00000000, // -
2, 8, B01100000, B01100000, B00000000, B00000000, B00000000, // .
4, 8, B01100000, B00011000, B00000110, B00000001, B00000000, // /
4, 8, B00111110, B01000001, B01000001, B00111110, B00000000, // 0
3, 8, B01000010, B01111111, B01000000, B00000000, B00000000, // 1
4, 8, B01100010, B01010001, B01001001, B01000110, B00000000, // 2
4, 8, B00100010, B01000001, B01001001, B00110110, B00000000, // 3
4, 8, B00011000, B00010100, B00010010, B01111111, B00000000, // 4
4, 8, B00100111, B01000101, B01000101, B00111001, B00000000, // 5
4, 8, B00111110, B01001001, B01001001, B00110000, B00000000, // 6
4, 8, B01100001, B00010001, B00001001, B00000111, B00000000, // 7
4, 8, B00110110, B01001001, B01001001, B00110110, B00000000, // 8
4, 8, B00000110, B01001001, B01001001, B00111110, B00000000, // 9
2, 8, B01010000, B00000000, B00000000, B00000000, B00000000, // :
2, 8, B10000000, B01010000, B00000000, B00000000, B00000000, // ;
3, 8, B00010000, B00101000, B01000100, B00000000, B00000000, // <
3, 8, B00010100, B00010100, B00010100, B00000000, B00000000, // =
3, 8, B01000100, B00101000, B00010000, B00000000, B00000000, // >
4, 8, B00000010, B01011001, B00001001, B00000110, B00000000, // ?
5, 8, B00111110, B01001001, B01010101, B01011101, B00001110, // @
4, 8, B01111110, B00010001, B00010001, B01111110, B00000000, // A
4, 8, B01111111, B01001001, B01001001, B00110110, B00000000, // B
4, 8, B00111110, B01000001, B01000001, B00100010, B00000000, // C
4, 8, B01111111, B01000001, B01000001, B00111110, B00000000, // D
4, 8, B01111111, B01001001, B01001001, B01000001, B00000000, // E
4, 8, B01111111, B00001001, B00001001, B00000001, B00000000, // F
4, 8, B00111110, B01000001, B01001001, B01111010, B00000000, // G
4, 8, B01111111, B00001000, B00001000, B01111111, B00000000, // H
3, 8, B01000001, B01111111, B01000001, B00000000, B00000000, // I
4, 8, B00110000, B01000000, B01000001, B00111111, B00000000, // J
4, 8, B01111111, B00001000, B00010100, B01100011, B00000000, // K
4, 8, B01111111, B01000000, B01000000, B01000000, B00000000, // L
5, 8, B01111111, B00000010, B00001100, B00000010, B01111111, // M
5, 8, B01111111, B00000100, B00001000, B00010000, B01111111, // N
4, 8, B00111110, B01000001, B01000001, B00111110, B00000000, // O
4, 8, B01111111, B00001001, B00001001, B00000110, B00000000, // P
4, 8, B00111110, B01000001, B01000001, B10111110, B00000000, // Q
4, 8, B01111111, B00001001, B00001001, B01110110, B00000000, // R
4, 8, B01000110, B01001001, B01001001, B00110010, B00000000, // S
5, 8, B00000001, B00000001, B01111111, B00000001, B00000001, // T
4, 8, B00111111, B01000000, B01000000, B00111111, B00000000, // U
5, 8, B00001111, B00110000, B01000000, B00110000, B00001111, // V
5, 8, B00111111, B01000000, B00111000, B01000000, B00111111, // W
5, 8, B01100011, B00010100, B00001000, B00010100, B01100011, // X
5, 8, B00000111, B00001000, B01110000, B00001000, B00000111, // Y
4, 8, B01100001, B01010001, B01001001, B01000111, B00000000, // Z
2, 8, B01111111, B01000001, B00000000, B00000000, B00000000, // [
4, 8, B00000001, B00000110, B00011000, B01100000, B00000000, // \ backslash
2, 8, B01000001, B01111111, B00000000, B00000000, B00000000, // ]
3, 8, B00000010, B00000001, B00000010, B00000000, B00000000, // hat
4, 8, B01000000, B01000000, B01000000, B01000000, B00000000, // _
2, 8, B00000001, B00000010, B00000000, B00000000, B00000000, // `
4, 8, B00100000, B01010100, B01010100, B01111000, B00000000, // a
4, 8, B01111111, B01000100, B01000100, B00111000, B00000000, // b
4, 8, B00111000, B01000100, B01000100, B00101000, B00000000, // c
4, 8, B00111000, B01000100, B01000100, B01111111, B00000000, // d
4, 8, B00111000, B01010100, B01010100, B00011000, B00000000, // e
3, 8, B00000100, B01111110, B00000101, B00000000, B00000000, // f
4, 8, B10011000, B10100100, B10100100, B01111000, B00000000, // g
4, 8, B01111111, B00000100, B00000100, B01111000, B00000000, // h
3, 8, B01000100, B01111101, B01000000, B00000000, B00000000, // i
4, 8, B01000000, B10000000, B10000100, B01111101, B00000000, // j
4, 8, B01111111, B00010000, B00101000, B01000100, B00000000, // k
3, 8, B01000001, B01111111, B01000000, B00000000, B00000000, // l
5, 8, B01111100, B00000100, B01111100, B00000100, B01111000, // m
4, 8, B01111100, B00000100, B00000100, B01111000, B00000000, // n
4, 8, B00111000, B01000100, B01000100, B00111000, B00000000, // o
4, 8, B11111100, B00100100, B00100100, B00011000, B00000000, // p
4, 8, B00011000, B00100100, B00100100, B11111100, B00000000, // q
4, 8, B01111100, B00001000, B00000100, B00000100, B00000000, // r
4, 8, B01001000, B01010100, B01010100, B00100100, B00000000, // s
3, 8, B00000100, B00111111, B01000100, B00000000, B00000000, // t
4, 8, B00111100, B01000000, B01000000, B01111100, B00000000, // u
5, 8, B00011100, B00100000, B01000000, B00100000, B00011100, // v
5, 8, B00111100, B01000000, B00111100, B01000000, B00111100, // w
5, 8, B01000100, B00101000, B00010000, B00101000, B01000100, // x
4, 8, B10011100, B10100000, B10100000, B01111100, B00000000, // y
3, 8, B01100100, B01010100, B01001100, B00000000, B00000000, // z
3, 8, B00001000, B00110110, B01000001, B00000000, B00000000, // {
1, 8, B01111111, B00000000, B00000000, B00000000, B00000000, // |
3, 8, B01000001, B00110110, B00001000, B00000000, B00000000, // }
4, 8, B00001000, B00000100, B00001000, B00000100, B00000000, // ~
};
int DIN = 11; // DIN pin of MAX7219 module
int CLK = 13; // CLK pin of MAX7219 module
int CS = 10; // CS pin of MAX7219 module
int maxInUse = 4;
MaxMatrix m(DIN, CS, CLK, maxInUse);
byte buffer[10];
char text[]= "Hello Eagler8"; // Scrolling text
void setup() {
m.init(); // module initialize
m.setIntensity(0); // dot matix intensity 0-15
}
void loop() {
printStringWithShift(text, 100); // (text, scrolling speed)
}
// Display=the extracted characters with scrolling
void printCharWithShift(char c, int shift_speed) {
if (c < 32) return;
c -= 32;
memcpy_P(buffer, CH + 7 * c, 7);
m.writeSprite(32, 0, buffer);
m.setColumn(32 + buffer[0], 0);
for (int i = 0; i < buffer[0] + 1; i++)
{
delay(shift_speed);
m.shiftLeft(false, false);
}
}
// Extract the characters from the text string
void printStringWithShift(char* s, int shift_speed) {
while (*s != 0) {
printCharWithShift(*s, shift_speed);
s++;
}
}

復制代碼

帳號		自動登錄	找回密碼
密碼			立即注冊

久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

【Arduino】108種傳感器模塊系列實驗（資料+代碼+圖形+仿真）