RING EQU 22H
ORG 0000H
AJMP MAIN
ORG 0003H
AJMP INT0SUB
ORG 000BH
AJMP T0INT
ORG 0013H
AJMP INT1SUB
ORG 001BH
AJMP T1INT
ORG 0040H
MAIN:MOV R1,#30;初設搶答時間為30s
MOV R2,#60;初設答題時間為60s
MOV TMOD,#11H;設置定時器工作于方式1
MOV TH0,#0FH
MOV TL0,#0B1H;越高發聲頻率越高，越尖
MOV TH1,#3CH
MOV TL1,#0B0H;50ms為一次溢出中斷
SETB EA
SETB ET0
SETB ET1
SETB EX0
SETB EX1;允許4個中斷，T0/T1/INT0/INT1
CLR OK
CLR RING
SETB TR1
SETB TR0;一開始就運行定時器，以開始顯示FFF，若要重新計數，重置TH1/TL1就行
;=====查詢程序=======
START:MOV R5,#0BH
MOV R4,#0BH
MOV R3,#0BH
ACALL DISPLAY;未開始搶答時候顯示FFF
JB P3.0,NEXT
ACALL DELAY
JB P3.0,NEXT;去抖動，如果“開始”按下就向下執行，否則跳到非法搶答查詢
ACALL BARK;按鍵發聲
MOV A,R1
MOV R6,A;送R1->R6,因為R1中保存了搶答時間
SETB OK;搶答標志位，勇于COUNT程序中半段是否查詢搶答
MOV R7,#01H;讀搶答鍵數據信號標志，這里表示只讀一次有用信號
MOV R3,#0AH;搶答只顯示計時，滅號數
AJMP COUNT;進入倒計時程序，“查詢有效搶答的程序”在COUNT里面
NEXT:JNB P1.0,FALSE1
JNB P1.1,FALSE2
JNB P1.2,FALSE3
JNB P1.3,FALSE4
JNB P1.4,FALSE5
JNB P1.5,FALSE6
JNB P1.6,FALSE7
JNB P1.7,FALSE8
AJMP START
;====非法搶答處理程序=====
FALSE1:MOV R3,#01H
AJMP ERROR
FALSE2:MOV R3,#02H
AJMP ERROR
FALSE3:MOV R3,#03H
AJMP ERROR
FALSE4:MOV R3,#04H
AJMP ERROR
FALSE5:MOV R3,#05H
AJMP ERROR
FALSE6:MOV R3,#06H
AJMP ERROR
FALSE7:MOV R3,#07H
AJMP ERROR
FALSE8:MOV R3,#08H
AJMP ERROR
;======INT0（搶答時間R1調整程序）=====
INT0SUB:MOV A,R1
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY;現在兩個時間LED上顯示R1
JNB P3.4,INC0;P3.4為+1S鍵，如按下跳到INC0
JNB P3.5,DEC0;P3.5為-1s鍵，如按下跳到DEC0
JNB P3.1,BACK0;P3.1為確定鍵，如按下跳到BACK0
AJMP INT0SUB
INC0:MOV A,R1
CJNE A,#63H,ADD0;如果不是99，R2加1，如果加到99，R1就置0，重新加起
MOV R1,#00H
ACALL DELAY1
AJMP INT0SUB
ADD0:INC R1
ACALL DELAY1
AJMP INT0SUB
DEC0:MOV A,R1
JZ SETR1;如果R1為0，R1就置99
DEC R1
ACALL DELAY1
AJMP INT0SUB
SETR1:MOV R1,#63H
ACALL DELAY1
AJMP INT0SUB
BACK0:RETI
;=====INT1（回答時間R2調整程序）=====
INT1SUB:MOV A,R2
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY
JNB P3.4,INC1
JNB P3.5,DEC1
JNB P3.1,BACK1
AJMP INT1SUB
INC1:MOV A,R2
CJNE A,#63H,ADD1
MOV R2,#00H
ACALL DELAY1
AJMP INT1SUB
ADD1:INC R2
ACALL DELAY1
AJMP INT1SUB
DEC1:MOV A,R2
JZ SETR2
DEC R2
ACALL DELAY1
AJMP INT1SUB
SETR2:MOV R2,#63H
ACALL DELAY1
AJMP INT1SUB
BACK1:RETI
;=====倒計時程序（搶答倒計時和回答倒計時都調到該程序）======
REPEAT:MOV A,R2;使用錦囊時重新計時
MOV R6,A
CLR RING
COUNT:MOV R0,#00H;重置定時器中斷次數
MOV TH1,#3CH
MOV TL1,#0B0H;重置定時器
RECOUNT:MOV A,R6;R6保存了倒計時間，之前應先將搶答或答題時間給R6
MOV B,#0AH
DIV AB;除十分出個位/十位
MOV 30H,A;十位存于(30H)
MOV 31H,B;個位存于(31H)
MOV R5,30H;取十位
MOV R4,31H;取個位
MOV A,R6
SUBB A,#07H
JNC LARGER;大于5s調到LARGER,小于等于5s會提醒
MOV A,R0
CJNE A,#0AH,FULL;1s中0.5s向下運行
CLR RING
AJMP CHECK
FULL:CJNE A,#14H,CHECK;下面是1s的情況，響并顯示號數并請R0，重新計數
SETB RING
MOV A,R6
JZ QUIT;計時完畢
MOV R0,#00H
DEC R6;一秒標志減1
AJMP CHECK
LARGER:MOV A,R0
CJNE A,#14H,CHECK;如果1s向下運行，否則跳到查“停/顯示”
DEC R6;計時一秒R6自動減1
MOV R0,#00H
CHECK:JNB P3.1,QUIT;如按下停止鍵退出
JNB OK,CHECKK;只在回答倒計時才有效
AJMP NEXTT
CHECKK:JNB P3.0,REPEAT;判斷是否使用錦囊
NEXTT:ACALL DISPLAY
JB OK,ACOUNT;如果是搶答倒計時，如是則查詢搶答，否則跳過查詢繼續倒數（這里起到鎖搶答作用）
AJMP RECOUNT
ACOUNT:MOV A,36H
JNB ACC.0,TRUE1
JNB ACC.1,TRUE2
JNB ACC.2,TRUE3
JNB ACC.3,TRUE4
JNB ACC.4,TRUE5
JNB ACC.5,TRUE6
JNB ACC.6,TZ1
JNB ACC.7,TZ2
AJMP RECOUNT
TZ1:JMP TRUE7
TZ2:JMP TRUE8
QUIT:CLR OK;如果按下了“停止”執行的程序
CLR RING
AJMP START
;=====正常搶答處理程序=======
TRUE1:ACALL BARK
MOV A,R2
MOV R6,A;搶答時間R2送R6
MOV R3,#01H
CLR OK;因為答題的計時不在查詢搶答，所以就鎖了搶答
AJMP COUNT
TRUE2:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#02H
CLR OK
AJMP COUNT
TRUE3:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#03H
CLR OK
AJMP COUNT
TRUE4:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#04H
CLR OK
AJMP COUNT
TRUE5:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#05H
CLR OK
AJMP COUNT
TRUE6:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#06H
CLR OK
AJMP COUNT
TRUE7:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#07H
CLR OK
AJMP COUNT
TRUE8:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#08H
CLR OK
AJMP COUNT
;=====犯規搶答程序=========
ERROR:MOV R0,#00H
MOV TH1,#3CH
MOV TL1,#0B0H
MOV 34H,R3;犯規號數暫存與（34H)
HERE:MOV A,R0
CJNE A,#06H,FLASH;0.3s向下運行->滅并停響
CLR RING
MOV R3,#0AH
MOV R4,#0AH
MOV R5,#0AH;三燈全滅
AJMP CHECK1
FLASH:CJNE A,#0CH,CHECK1;下面是0.8s的情況，響并顯示號數并清R0，重新計
SETB RING
MOV R0,#00H
MOV R3,34H;取回號數
MOV R5,#0BH
MOV R4,#0BH;顯示FF和號數
AJMP CHECK1
CHECK1:JNB P3.1,QUIT
ACALL DISPLAY
AJMP HERE
QUIT1:CLR RING
CLR OK
AJMP START
;=====顯示程序=====
DISPLAY:MOV DPTR,#DAT1;查表顯示程序，利用P0口做段選碼輸出/P2低三位做位選嗎輸出
MOV A,R3
MOVC A,@A+DPTR
MOV P2,#0FEH
MOV P0,A
ACALL DELAY2
MOV DPTR,#DAT2
MOV A,R5
MOVC A,@A+DPTR
MOV P2,#0FDH
MOV P0,A
ACALL DELAY2
MOV A,R4
MOVC A,@A+DPTR
MOV P2,#0FBH
MOV P0,A
ACALL DELAY2
RET
DAT1:DB 00H,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH,00H,71H;滅、1、2、3、4、5、6、7、8、9、滅、F
DAT2:DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH,00H,71H;0、1、2、3、4、5、6、7、8、9、滅、F
;======加減時間延時（起到不會按下就加N個數）=====
DELAY1:MOV 35H,#08H
LOOP0:ACALL DISPLAY
DJNZ 35H,LOOP0
RET
;======延時4236個機器周期（去抖動用到）=====
DELAY:MOV 32H,#12H
LOOP:MOV 33H,#0AFH
LOOP1:DJNZ 33H,LOOP1
DJNZ 32H,LOOP
RET
;======延時4236個機器周期（顯示用到）=======
DELAY2:MOV 32H,#43H
LOOP3:MOV 33H,#1EH
MOV A,R7;每隔60~70個機器周期讀一次P1口，全為1時為無效數據，繼續讀，有一個不為1時，轉到正常強大處理
JNZ AAAA1;沒讀到有效數據時繼續轉到AAAA1
LOOP2:DJNZ 33H,LOOP2
DJNZ 32H,LOOP3
RET
;=======讀搶答按鍵數據口程序========
;由于在度搶答數據口的時候，單片機首先進入倒計時程序，再調用顯示程序，最后哎檢測安檢口
;然而在檢測安檢口時動態掃描要調用三次（4MS）延時程序。這樣就會導致讀數據口出現滯后，造成1號優先最高，8號最低
;故采用在延時子程序中加了讀數據口程序，保證了靈敏度和可靠性
AAAA1:MOV A,P1
CJNE A,#0FFH,AA1; 當不全為1時的數據為有效數據
AA0:MOV 36H,A;將有效數據送到36H暫存
AJMP LOOP2
AA1:DEC R7
AJMP AA0
;=====發聲程序======
BARK:SETB RING
ACALL DELAY1
ACALL DELAY1
CLR RING;按鍵發聲
RET
;=====T0溢出中斷（響鈴程序）======
T0INT:MOV TH0,#0ECH
MOV TL0,#0FFH
JNB RING,OUT
CPL P3.6;RING標志位為1時P3.6口不短取反使喇叭發出一定頻率的聲音
OUT:RETI
;=====T1溢出中斷（計時程序）======
T1INT:MOV TH1,#3CH
MOV TL1,#0B0H
INC R0
RETI
END
|
QQ好友和群
QQ空間
騰訊微博
騰訊朋友
收藏
淘帖
頂
踩
