2016-6-2 09:36 上傳
點擊文件名下載附件
;這是關(guān)于DS18B20的讀寫程序,數(shù)據(jù)腳P2.2,
晶振11.0592mhz
;溫度傳感器18B20匯編程序,采用器件默認的12位轉(zhuǎn)化,最大轉(zhuǎn)化時間750微秒
;可以將檢測到的溫度直接顯示到AT89C51開發(fā)實驗板的兩個數(shù)碼管上
;顯示溫度00到99度,很準確哦~~無需校正!
ORG 0000H
;單片機內(nèi)存分配申明!
TEMPER_L EQU 29H;用于保存讀出溫度的低8位
TEMPER_H EQU 28H;用于保存讀出溫度的高8位
FLAG1 EQU 38H;是否檢測到DS18B20標志位
a_bit equ 20h ;數(shù)碼管個位數(shù)存放內(nèi)存位置
b_bit equ 21h ;數(shù)碼管十位數(shù)存放內(nèi)存位置
MAIN:
LCALL GET_TEMPER;調(diào)用讀溫度子程序
;進行溫度顯示,這里我們考慮用網(wǎng)站提供的兩位數(shù)碼管來顯示溫度
;顯示范圍00到99度,顯示精度為1度
;因為12位轉(zhuǎn)化時每一位的精度為0.0625度,我們不要求顯示小數(shù)所以可以拋棄29H的低4位
;將28H中的低4位移入29H中的高4位,這樣獲得一個新字節(jié),這個字節(jié)就是實際測量獲得的溫度
;這個轉(zhuǎn)化溫度的方法可是我想出來的哦~~非常簡潔無需乘于0.0625系數(shù)
MOV A,29H
MOV C,40H;將28H中的最低位移入C
RRC A
MOV C,41H
RRC A
MOV C,42H
RRC A
MOV C,43H
RRC A
MOV 29H,A
LCALL DISPLAY;調(diào)用數(shù)碼管顯示子程序
CPL P1.0
AJMP MAIN
; 這是DS18B20復位初始化子程序
INIT_1820:
SETB P2.2
NOP
CLR P2.2
;主機發(fā)出延時537微秒的復位低脈沖
MOV R1,#3
TSR1:MOV R0,#107
DJNZ R0,$
DJNZ R1,TSR1
SETB P2.2;然后拉高數(shù)據(jù)線
NOP
NOP
NOP
MOV R0,#25H
TSR2:
JNB P2.2,TSR3;等待DS18B20回應
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標志位,表示DS1820存在
CLR P1.7;檢查到DS18B20就點亮P1.7LED
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標志位,表示DS1820不存在
CLR P1.1
LJMP TSR7
TSR5:
MOV R0,#117
TSR6:
DJNZ R0,TSR6 ; 時序要求延時一段時間
TSR7:
SETB P2.2
RET
; 讀出轉(zhuǎn)換后的溫度值
GET_TEMPER:
SETB P2.2
LCALL INIT_1820;先復位DS18B20
JB FLAG1,TSS2
CLR P1.2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
CLR P1.3;DS18B20已經(jīng)被檢測到!!!!!!!!!!!!!!!!!!
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發(fā)出溫度轉(zhuǎn)換命令
LCALL WRITE_1820
;這里通過調(diào)用顯示子程序?qū)崿F(xiàn)延時一段時間,等待AD轉(zhuǎn)換結(jié)束,12位的話750微秒
LCALL DISPLAY
LCALL INIT_1820;準備讀溫度前先復位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發(fā)出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的溫度數(shù)據(jù)保存到35H/36H
CLR P1.4
RET
;寫DS18B20的子程序(有具體的時序要求)
WRITE_1820:
MOV R2,#8;一共8位數(shù)據(jù)
CLR C
WR1:
CLR P2.2
MOV R3,#5
DJNZ R3,$
RRC A
MOV P2.2,C
MOV R3,#21
DJNZ R3,$
SETB P2.2
NOP
DJNZ R2,WR1
SETB P2.2
RET
; 讀DS18B20的程序,從DS18B20中讀出兩個字節(jié)的溫度數(shù)據(jù)
READ_18200:
MOV R4,#2 ; 將溫度高位和低位從DS18B20中讀出
MOV R1,#29H ; 低位存入29H(TEMPER_L),高位存入28H(TEMPER_H)
RE00:
MOV R2,#8;數(shù)據(jù)一共有8位
RE01:
CLR C
SETB P2.2
NOP
NOP
CLR P2.2
NOP
NOP
NOP
SETB P2.2
MOV R3,#8
RE10:
DJNZ R3,RE10
MOV C,P2.2
MOV R3,#21
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
DEC R1
DJNZ R4,RE00
RET
;顯示子程序
display: mov a,29H;將29H中的十六進制數(shù)轉(zhuǎn)換成10進制
mov b,#10 ;10進制/10=10進制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個位在b
mov dptr,#numtab ;指定查表啟始地址
mov r0,#4
dpl1: mov r1,#250 ;顯示1000次
dplop: mov a,a_bit ;取個位數(shù)
MOVC A,@A+DPTR ;查個位數(shù)的7段代碼
mov p0,a ;送出個位的7段代碼
clr p2.7 ;開個位顯示
acall d1ms ;顯示1ms
setb p2.7
mov a,b_bit ;取十位數(shù)
MOVC A,@A+DPTR ;查十位數(shù)的7段代碼
mov p0,a ;送出十位的7段代碼
clr p2.6 ;開十位顯示
acall d1ms ;顯示1ms
setb p2.6
djnz r1,dplop ;100次沒完循環(huán)
djnz r0,dpl1 ;4個100次沒完循環(huán)
ret
;1MS延時
D1MS: MOV R7,#80
DJNZ R7,$
RET
;實驗板上的7段數(shù)碼管0～9數(shù)字的共陰顯示代碼
numtab: DB 0CFH,03H,5DH,5BH,93H,0DAH,0DEH,43H,0DFH,0DBH
end
;溫度傳感器18B20匯編程序,采用器件默認的12位轉(zhuǎn)化,最大轉(zhuǎn)化時間750微秒
;將溫度數(shù)據(jù)通過串口發(fā)送出去，波特率2400
;本程序?qū)锳T89C51實驗開發(fā)板編寫.適合12晶振
;本程序經(jīng)過驗證,可以顯示溫度+/-和兩位整數(shù)溫度和兩位小數(shù)溫度數(shù)據(jù)
DOT EQU 30H
ZHENGSHU EQU 31H
FLAG1 EQU 38H ;是否檢測到DS18B20的標志位
;定義溫度數(shù)據(jù)
DIS_1 EQU 32H ;符號
DIS_2 EQU 33H ;十位
DIS_3 EQU 34H ;個位
DIS_4 EQU 35H ;小數(shù)點后第一位
DIS_5 EQU 36H ;小數(shù)點后第二位
WDDATA BIT P2.2 ;定義DS18B20的數(shù)據(jù)腳為P2.2端口
ORG 0000H
;以下為主程序進行CPU中斷方式設置
CLR EA ;關(guān)閉總中斷
MOV SCON,#50H ;設置成串口1方式
MOV TMOD,#20H ;波特率發(fā)生器T1工作在模式2上
MOV TH1,#0F3H ;預置初值(按照波特率2400BPS預置初值)
MOV TL1,#0F3H ;預置初值(按照波特率2400BPS預置初值)
SETB TR1 ;啟動定時器T1
;以上完成串口2400通訊初始化設置
;-------------------------
; 主程序
;-------------------------
MAIN:
LCALL INIT_1820 ;調(diào)用復位DS18B20子程序
MAIN1:
LCALL GET_TEMPER;調(diào)用讀溫度子程序
LCALL FORMULA ;通過公式計算,小數(shù)點后顯示兩位
LCALL BCD
LCALL DISPLAY ;調(diào)用串口顯示子程序
LCALL DELAY500 ;延時0.5秒
LCALL DELAY500 ;延時0.5秒
LCALL DELAY500 ;延時0.5秒
AJMP MAIN1
;-------------------------
; DS18B20復位初始化程序
;-------------------------
INIT_1820:
SETB WDDATA
NOP
CLR WDDATA
;主機發(fā)出延時540微秒的復位低脈沖
MOV R0,#36
LCALL DELAY
SETB WDDATA;然后拉高數(shù)據(jù)線
NOP
NOP
MOV R0,#36
TSR2:
JNB WDDATA,TSR3;等待DS18B20回應
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標志位,表示DS1820存在
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標志位,表示DS1820不存在
LJMP TSR7
TSR5:
MOV R0,#06BH
TSR6:
DJNZ R0,TSR6 ;復位成功!時序要求延時一段時間
TSR7:
SETB WDDATA
RET
;-------------------
; 讀出轉(zhuǎn)換后的溫度值
;-------------------
GET_TEMPER:
SETB WDDATA ; 定時入口
LCALL INIT_1820 ;先復位DS18B20
JB FLAG1,TSS2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發(fā)出溫度轉(zhuǎn)換命令
LCALL WRITE_1820
MOV R0,#50 ;等待AD轉(zhuǎn)換結(jié)束,12位的話750微秒.
LCALL DELAY
LCALL INIT_1820 ;準備讀溫度前先復位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發(fā)出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的九個字節(jié)數(shù)據(jù)保存到60H-68H
RET
;----------------------------------
;寫DS18B20的子程序(有具體的時序要求)
;----------------------------------
WRITE_1820:
MOV R2,#8 ;一共8位數(shù)據(jù)
CLR C
WR1:
CLR WDDATA
MOV R3,#6
DJNZ R3,$
RRC A
MOV WDDATA,C
MOV R3,#24
DJNZ R3,$
SETB WDDATA
NOP
DJNZ R2,WR1
SETB WDDATA
RET
;--------------------------------------------------
; 讀DS18B20的程序,從DS18B20中讀出九個字節(jié)的數(shù)據(jù)
;--------------------------------------------------
READ_18200:
MOV R4,#9
MOV R1,#60H ; 存入60H開始的九個單元
RE00:
MOV R2,#8
RE01:
CLR C
SETB WDDATA
NOP
NOP
CLR WDDATA
NOP
NOP
NOP
SETB WDDATA
MOV R3,#09
RE10:
DJNZ R3,RE10
MOV C,WDDATA
MOV R3,#23
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
INC R1
DJNZ R4,RE00
RET
;------------------------
;溫度計算子程序
;------------------------
FORMULA: ; 按公式：T實際=(T整數(shù)-0.25)+( M每度-M剩余)/ M每度
;計算出實際溫度，整數(shù)部分和小數(shù)部分分別存于ZHENGSHU單元和DOT單元
;將61H中的低4位移入60H中的高4位，得到溫度的整數(shù)部分，并存于ZHENGSHU單元
MOV 29H,61H
MOV A,60H
MOV C,48H
RRC A
MOV C,49H
RRC A
MOV C,4AH
RRC A
MOV C,4BH
RRC A
MOV ZHENGSHU,A
; ( M每度-M剩余)/ M每度,小數(shù)值存于A中
MOV A,67h
SUBB A,66h
MOV B,#64H
MUL AB
MOV R4,B
MOV R5,A
MOV R7,67H
LCALL DIV457
MOV A,R3
;再減去0.25，實際應用中減去25
SUBB A,#19H
MOV DOT,A ;小數(shù)部分存于DOT中
MOV A,ZHENGSHU
SUBB A,#00H ;整數(shù)部分減去來自小數(shù)部分的借位
MOV ZHENGSHU,A
MOV C,4BH
JNC ZHENG ;是否為負數(shù)
CPL A
INC A
MOV DIS_1,#2DH ; 零度以下時,第一位顯示"-"號
MOV ZHENGSHU,A
ZHENG:
MOV DIS_1,#2BH ; 零度以上時,第一位顯示"+"號
RET
;------------------------
;雙字節(jié)除以單字節(jié)子程序
;------------------------
DIV457: CLR C
MOV A,R4
SUBB A,R7
JC DV50
SETB OV ;商溢出
RET
DV50: MOV R6,#8 ;求平均值（R4R5／R7－→R3）
DV51: MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DV52
MOV R4,A
DV52: CPL C
MOV A,R3
RLC A
MOV R3,A
DJNZ R6,DV51
MOV A,R4 ;四舍五入
ADD A,R4
JC DV53
SUBB A,R7
JC DV54
DV53: INC R3
DV54: CLR OV
RET
;---------------------
;轉(zhuǎn)換成非壓縮的BCD碼
;---------------------
BCD: MOV A,ZHENGSHU
MOV B,#0AH
DIV AB
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
MOV DIS_2,A
MOV DIS_3,B
MOV A,DIS_3
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
mov DIS_3,A
MOV A,DOT
MOV B,#0AH
DIV AB
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
MOV DIS_4,A
MOV DIS_5,B
MOV A,DIS_5
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
mov DIS_5,A
RET
;----------------------
;串口顯示數(shù)據(jù)子程序
;----------------------
DISPLAY:
CLR TI
MOV A,DIS_1
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示+/-
CLR TI
MOV A,DIS_2
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示整數(shù)第一位
CLR TI
MOV A,DIS_3
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示整數(shù)第二位
CLR TI
MOV A,#2EH
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)點
CLR TI
MOV A,DIS_4
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)第一位
CLR TI
MOV A,DIS_5
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)第一位
CLR TI
MOV A,#0DH;換行
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示
CLR TI
MOV A,#0AH;換行
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示
RET
;----------------------
;延時子程序
;----------------------
;為保證DS18B20的嚴格I/O時序，需要做較精確的延時
;在DS18B20操作中，用到的延時有15 μs，90 μs，270 μs，540 μs
;因這些延時均為15 μs的整數(shù)倍，因此可編寫一個DELAY15（n）函數(shù)
DELAY: ;11.05962M晶振
LOOP: MOV R1,#06H
LOOP1: DJNZ R1,LOOP1
DJNZ R0,LOOP
RET
;500毫秒延時子程序，占用R4、R5
DELAY500:MOV R4,#248
DA222:MOV R5,#248
DJNZ R5,$
DJNZ R4,DA222
RET
END
