; ledpwm.asm --- drive a blue LED with PWM 21/04/2006
; Copyright (c) 2006 John Honniball
.include "m8def.inc"
.org 0x0000
; 端口 B 位 2 上的LED
.equ LED_PORT = PortB
.equ LED_BIT = 2
; 該程序驅動連接到 AVR 的 I/O 端口的單個 LED。 它將 LED 的陰極連接到 AVR 引腳，
;LED 的陽極通過電阻器。 該電阻的值取決于 LED 的顏色，但通常為幾百歐姆。
;我們通過脈寬調制 （PWM） 控制 LED 的亮度，
; 就像脈動那樣地周期運動或變化 從未完全“熄滅昏暗狀態”到全亮度再調至昏暗狀態，然后再變回來。
;為此，設置最小亮度、最大亮度值。
.equ MIN_BRIGHT = 15 ;最小亮度
.equ MAX_BRIGHT = 255 ;最大亮度
; 此值控制 LED 從亮到暗的循環速度。 是的我們為亮度的每一步生成的PWM周期數
;坡道，上坡和坡道。 數字越大，脈動越慢。
.equ N_CYCLES = 6 ;周期數
; 重置后開始執行程序
ldi r16,low(RAMEND) ; 初始化堆棧到RAM頂部
out SPL,r16
ldi r16,high(RAMEND)
out SPH,r16
; 初始化硬件
ldi r16,0xff ; 將端口B設置為所有輸出
out DDRB,r16
sbi LED_PORT,LED_BIT ;通過將輸出引腳設置為高電平關閉藍色LED
; 從LED處于最低水平開始，然后上升到最大水平
dopwm: ldi r17,MIN_BRIGHT ; R17保持當前亮度水平
adjust_1: ldi r18,N_CYCLES ; R18計算PWM周期，從而計算脈動速度
adjust_2: cbi LED_PORT,LED_BIT ; 輸出引腳低，LED亮起
mov r16,r17 ;R16控制延遲長度（=R17）
rcall delayn4us ;調用延遲子程序
sbi LED_PORT,LED_BIT ; 輸出引腳高，LED熄滅
ldi r16,255
sub r16,r17 ; R16控制延遲長度（=255-R17）
rcall delayn4us ; 調用延遲子程序
dec r18 ;遞減PWM周期計數器
brne adjust_2
inc r17 ; 亮度增加一步
brne adjust_1
; 現在逐漸降低到最小亮度
ldi r17,MAX_BRIGHT ;R17 保持當前亮度水平
adjust_3: ldi r18,N_CYCLES ;R18 計算 PWM 周期，從而計算脈動速度
adjust_4: cbi LED_PORT,LED_BIT ;輸出引腳低電平，LED 亮起
MOV R16,R17 ;R16 控制延遲長度 （= R17）
rcall delayn4us ;呼叫延遲子例程
sbi LED_PORT,LED_BIT ;輸出引腳高電平，LED 熄滅
ldi R16,255
sub R16,R17 ;R16 控制延遲長度 （= 255 - R17）
rcall delayn4us ;呼叫延遲子例程
dec R18 ;遞減PWM周期計數器
brne adjust_4
dec R17 ;亮度降低一級
CPI r17,MIN_BRIGHT ;我們達到最低限度了嗎？
brne adjust_3
rjmp dopwm ; 循環回到開始
; delayn 4US
;延遲 （R16 * 4） 微秒
delayn4us: tst r16 ; R16 = 0？（無延遲）
breq dly4
dly2: ldi r24,low(16)
ldi r25,high(16)
dly3: sbiw r24,1 ; 2 個周期
brne dly3 ; 2 個周期
dec r16
brne dly2
dly4: ret ;返回
|
QQ好友和群
QQ空間
騰訊微博
騰訊朋友
收藏
淘帖
頂
踩
